1. マウス
2. キーコード

キー・マウスの状態を取得します。キー・マウスが押されている間はTrue、押されていない間はFalseを返します。キーボードの操作を行うにはKBD関数、マウスの操作を行うにはBTN関数を使います。

構文

1. Boolean = GETKEYSTATE( キーコード )

引数

キーコード （#getkeystate）必須

状態を知りたいキーコード

戻り値

TRUE：クリックがあった、　FALSE：なし

※マウスクリック

1. VK_RBUTTON（右）
2. VK_LBUTTON（左）
3. VK_MBUTTON（中）

※トグルキー状態

1. TGL_IME（IME）
2. TGL_NUMLOCK（NumLock）
3. TGL_CAPSLOCK（CapsLock）
4. TGL_SCROLLLOCK（ScrollLock）
5. TGL_KANALOCK（カタカナ）

マウス

マウスのクリックの状態を取得します。

以下は左クリックの状態を吹き出しに表示します。押されている間は1、押されていないときは0を表示します。

SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")

WHILE TRUE
	FUKIDASI(GETKEYSTATE(VK_LBUTTON))
	SLEEP(0.001)
WEND

//////////////////////////////////////////////////
// 【引数】
//   
// 【戻り値】
//   
//////////////////////////////////////////////////
PROCEDURE forceQuit()
	EXITEXIT
FEND

トグルキー

トグルキーとは押すたびに2つの状態（オン・オフ）が変わるキーのことをいい、半角/全角キー、NumLockキー、CapsLockキー、ScrollLockキー、かなロックキーの5つがあります。

半角/全角キー

半角入力と全角入力を切り替えます。

NumLockキー

テンキーで数字入力と移動キーを切り替えます。

CapsLockキー

CapsLockのCapsとはCapital lettersの略で大文字を意味しています。CapsLockを有効にすることでアルファベット入力を大文字に固定することができます。

ScrollLockキー

画面上のカーソルの位置を固定し、表示範囲を上下左右にスクロールします。

かなロックキー

ローマ字入力とかな入力を切り替えます。かなロックキーがオンでかな入力、オフでローマ字入力です。

CapsLockのみは単独で状態を切り替えることができず、Shift＋CapsLockを組み合わせて押す必要があります。

以下はトグルキーの状態とGETKEYSTATE関数の戻り値の関係を表にしたものです。半角/全角以外はONになっていればTrueを返します。

以下はGETKEYSTATE関数のトグルキー状態とそれに対応するKBD関数の定数の関係を表したものです。

トグルキーはクリックするたびに状態が変わるので、まずGETKEYSTATE関数で状態を取得してからKBD関数でキーを押すか押さないかを判断する必要があります。

例えばNumLockを有効にしたいとき、GETKEYSTATE関数で現在の状態を確認してOFFになっているときのみKBD関数でNumLockキーを押すという処理を行います。このような処理を記述することで、現在の状態に関係なくNumLockがONにすることができます。

IF !GETKEYSTATE(TGL_NUMLOCK) THEN KBD(VK_NUMLOCK)

逆にNumLockを無効にしたいときは、現在の状態がONになっているときのみNumLockキーを押すという処理を行います。GETKEYSTATEの前に!があるかないかの違いのみです。

IF GETKEYSTATE(TGL_NUMLOCK) THEN KBD(VK_NUMLOCK)

特定のキーの長押しを検知

一つのキー

特定のキーを押してから離すまでの時間（単位：ミリ秒）で測定。以下はスペースキーを押してから離すまでの時間を返します。

DEF_DLL GetTickCount(): LONG: kernel32.dll
DIM key = VK_SPACE

REPEAT
	SLEEP(0.001)
UNTIL GETKEYSTATE(key)

DIM stime = GetTickCount()

REPEAT
	DIM time = GetTickCount() - stime
	FUKIDASI(time)
	SLEEP(0.001)
UNTIL !GETKEYSTATE(key)

PRINT time

特定のキーを押して指定時間以上で抜けます。以下はスペースキーが3000ミリ秒押し続けたらループを抜けます。

DEF_DLL GetTickCount(): LONG: kernel32.dll
DIM key = VK_SPACE

REPEAT
	SLEEP(0.001)
UNTIL GETKEYSTATE(key)

DIM stime = GetTickCount()

REPEAT
	DIM time = GetTickCount() - stime
	FUKIDASI(time)
	SLEEP(0.001)
UNTIL !GETKEYSTATE(key) OR time >= 3000

PRINT time

複数のキー

複数のキーを検知するには、論理演算子（AND、OR）で繋げて記述します。

以下はCtrlとSpaceの同時押しを検知するプログラムです。

REPEAT
	SLEEP(0.001)
UNTIL GETKEYSTATE(VK_CTRL) AND GETKEYSTATE(VK_SPACE)

仮想キーコード一覧

プログラム実行例

日本語入力をONにする

現在の入力モードが直接入力であれば半角/全角キーを押して日本語入力に切り替えます。

IF !GETKEYSTATE(TGL_IME) THEN KBD(VK_KANJI, CLICK)

日本語入力をOFFにする

現在の入力モードが日本語入力であれば半角/全角キーを押して直接入力に切り替えます。

IF GETKEYSTATE(TGL_IME) THEN KBD(VK_KANJI, CLICK)

NumLockをONにする

NumLockの状態を確認し、OFFであればNumLockキーを押してONにします。

IF !GETKEYSTATE(TGL_NUMLOCK) THEN KBD(VK_NUMLOCK)

NumLockをOFFにする

NumLockの状態を確認し、ONであればNumLockキーを押してOFFにします。

IF GETKEYSTATE(TGL_NUMLOCK) THEN KBD(VK_NUMLOCK)

CapsLockをONにする

CapsLockの状態を確認し、OFFであればCapsLockキーを押してONにします。

IF !GETKEYSTATE(TGL_CAPSLOCK) THEN KBD(VK_CAPITAL)

CapsLockをOFFにする

CapsLockの状態を確認し、ONであればCapsLockキーを押してOFFにします。

IF GETKEYSTATE(TGL_CAPSLOCK) THEN KBD(VK_CAPITAL)

ScrollLockをONにする

IF !GETKEYSTATE(TGL_SCROLLLOCK) THEN KBD(VK_SCROLL)

ScrollLockをOFFにする

IF GETKEYSTATE(TGL_SCROLLLOCK) THEN KBD(VK_SCROLL)

カナロックをONにする

IF !GETKEYSTATE(TGL_KANALOCK) THEN KBD(VK_KANA)

カナロックをOFFにする

IF GETKEYSTATE(TGL_KANALOCK) THEN KBD(VK_KANA)

関連記事

LOCKHARDEX関数 (スクリプト関数)

MMV関数 (スクリプト関数)

マウスカーソルを指定した座標に移動します。

MOUSEORG関数 (スクリプト関数)

マウス座標を相対座標にする、 またはマウスとキー情報を直接ウィンドウへ送ります。

MUSCUR関数 (スクリプト関数)

MUSCUR関数は、マウスカーソルの種別を数値で返す関数です。引数はなく、戻値はInteger型です。

SETHOTKEY関数 (スクリプト関数)

SETHOTKEY関数は、ホットキーを設定しProcedure関数を呼び出すことができる関数です。キーコードは仮想キーを指定します。関数の呼び出しに成功した場合はTRUE、失敗した場合はFALSEを返します。