Contents
- 1 ホットキーの設定/解除
- 2 ホットキーの呼び出しと文字入力を同時に行う方法
- 3 修飾子キー単独で検知
- 4 仮想キー一覧
- 5 プログラム実行例
- 5.1 画像をクリップボードにコピーする
- 5.2 アイドル時間を取得
- 5.3 マウスカーソル下のウィンドウの情報を吹き出しに表示
- 5.4 特定のキーを連打する
- 5.5 現在のカーソル位置を吹き出しに表示
- 5.6 プログラム実行時からの経過時間を表示（ESCで終了）
- 5.7 メールの受信を検知（Outlook）
- 5.8 フラッシュ暗算
- 5.9 マウスカーソル下のスクロールバー情報を取得
- 5.10 Yahoo!ファイナンスから米ドル・ユーロ・豪ドルのレートを取得
- 5.11 ファイルを開いているプロセスを調べる
- 5.12 キーボードからの入力を1文字ずつずらす
- 5.13 マウス位置の色を取得
- 5.14 キャレット（カーソル）位置を取得
- 5.15 CLKITEMで操作できる項目を取得
- 6 この記事は役に立ちましたか？
ホットキーを設定します。設定したホットキーを入力することによりプロシージャを呼び出すことができます。
「VK」は「Virtual Key」の略で仮想キー、「MOD」は「MODifier key」の略で修飾子キーを意味します。
修飾子キーを複数指定する場合はORで繋げます。
HOTKEY_VKはキーコード(数値)なので、文字に変換する場合は「CHR(HOTKEY_VK)」と記述します。
HOTKEY_MODから指定したキーが押されたかを判断するには 、「HOTKEY_MOD AND 修飾子キー」が0か0以外かで判断できます。「HOTKEY_MOD AND MOD_CONTROL」が0でなければCtrlが押されたということになります。
- 構文
- Boolean = SETHOTKEY( キーコード, 修飾子キー, Procedure名 )
- 引数
- キーコード （#sethotkey）必須
- 使用するキーコード
- 修飾子キー （#sethotkey）省略可
- （省略可、複数指定化）
MOD_ALT(Alt)
MOD_CONTROL(Ctrl)
MOD_SHIFT(Shift)
MOD_WIN(Win) - Procedure名 （String）省略可
- UWSC側の呼び出される Procedure名、省略された場合にはホットキーの解除
- 戻り値
- TRUE
- 成功
- FALSE
- 失敗
Procedure内にて変数 HOTKEY_VKにキーコード、HOTKEY_MODに修飾子キーが格納されている。
ホットキーの設定/解除
// ESCキーでforceQuit関数を呼び出す
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
// ESCキーで呼び出せるようにしたforceQuit関数を解除
SETHOTKEY(VK_ESC, EMPTYPARAM)
//////////////////////////////////////////////////
// 【引数】
//
// 【戻り値】
//
//////////////////////////////////////////////////
PROCEDURE forceQuit()
EXITEXIT
FENDすべてのホットキーを解除
以下のプログラムを実行すると設定されているすべてのホットキーを解除することができます。
FOR key = 1 TO 255
FOR modifier = 0 TO 3
SETHOTKEY(key, POWER(2, modifier))
NEXT
NEXTホットキーの呼び出しと文字入力を同時に行う方法
ホットキーでプロシージャを呼び出された際、その文字は入力されなくなります。プロシージャの呼び出した際にその文字も入力したい場合、呼び出したプロシージャ内に「KBD(HOTKEY_VK)」と記述することで文字入力ができるようになります。
以下はA〜Zにホットキーを設定し、keyInput関数を呼び出すプログラム。例えばキーボードでAと打つとプロシージャが呼び出されるがAが文字として入力はされませんが、KBD関数を使うことでプロシージャを呼び出しつつ文字も入力できるようにします。
以下のプログラムをKBD関数ありとなしで実行しメモ帳で文字入力をしてみると違いがわかると思います。
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
FOR key = VK_A TO VK_Z
SETHOTKEY(key, EMPTYPARAM, "keyInput")
NEXT
WHILE TRUE
SLEEP(0.001)
WEND
PROCEDURE keyInput()
KBD(HOTKEY_VK)
FEND
//////////////////////////////////////////////////
// 【引数】
//
// 【戻り値】
//
//////////////////////////////////////////////////
PROCEDURE forceQuit()
EXITEXIT
FEND修飾子キー単独で検知
検知されたキーの値を返します。
DIM keys[] = MOD_ALT, MOD_CONTROL, MOD_SHIFT, MOD_WIN
SETHOTKEY(EMPTYPARAM, MOD_ALT, "keyInput") // 1
SETHOTKEY(EMPTYPARAM, MOD_CONTROL, "keyInput") // 2
SETHOTKEY(EMPTYPARAM, MOD_SHIFT, "keyInput") // 4
SETHOTKEY(EMPTYPARAM, MOD_WIN, "keyInput") // 8
PROCEDURE keyInput()
PRINT HOTKEY_MOD
FEND仮想キー一覧
| 値 | 定数名 | キー |
|---|---|---|
| 8 | VK_BACK | Backspaceキー |
| 9 | VK_TAB | Tabキー |
| 12 | VK_CLEAR | Clearキー |
| 13 | VK_RETURN | Enterキー |
| 13 | VK_ENTER | Enterキー |
| 16 | VK_SHIFT | Shiftキー |
| 17 | VK_CTRL | Ctrlキー |
| 17 | VK_CONTROL | Ctrlキー |
| 18 | VK_ALT | Altキー |
| 18 | VK_MENU | Altキー |
| 19 | VK_PAUSE | Pauseキー |
| 20 | VK_CAPITAL | CapsLockキー |
| 21 | VK_KANA | IMEかなモード |
| 24 | VK_FINAL | IME final mode |
| 25 | VK_KANJI | IME漢字モード |
| 27 | VK_ESC | Escキー |
| 27 | VK_ESCAPE | Escキー |
| 28 | VK_CONVERT | 変換キー |
| 29 | VK_NONCONVERT | 無変換キー |
| 30 | VK_ACCEPT | IME accept |
| 31 | VK_MODECHANGE | IME mode change request |
| 32 | VK_SPACE | Spaceキー |
| 33 | VK_PRIOR | PageUpキー |
| 34 | VK_NEXT | PageDownキー |
| 35 | VK_END | Endキー |
| 36 | VK_HOME | Homeキー |
| 37 | VK_LEFT | ← |
| 38 | VK_UP | ↑ |
| 39 | VK_RIGHT | → |
| 40 | VK_DOWN | ↓ |
| 41 | VK_SELECT | |
| 42 | VK_PRINT | Printキー |
| 43 | VK_EXECUTE | Executeキー |
| 44 | VK_SNAPSHOT | Print Screenキー |
| 45 | VK_INSERT | Insertキー |
| 46 | VK_DELETE | Deleteキー |
| 47 | VK_HELP | Helpキー |
| 48 | VK_0 | 0キー |
| 49 | VK_1 | 1キー |
| 50 | VK_2 | 2キー |
| 51 | VK_3 | 3キー |
| 52 | VK_4 | 4キー |
| 53 | VK_5 | 5キー |
| 54 | VK_6 | 6キー |
| 55 | VK_7 | 7キー |
| 56 | VK_8 | 8キー |
| 57 | VK_9 | 9キー |
| 65 | VK_A | Aキー |
| 66 | VK_B | Bキー |
| 67 | VK_C | Cキー |
| 68 | VK_D | Dキー |
| 69 | VK_E | Eキー |
| 70 | VK_F | Fキー |
| 71 | VK_G | Gキー |
| 72 | VK_H | Hキー |
| 73 | VK_I | Iキー |
| 74 | VK_J | Jキー |
| 75 | VK_K | Kキー |
| 76 | VK_L | Lキー |
| 77 | VK_M | Mキー |
| 78 | VK_N | Nキー |
| 79 | VK_O | Oキー |
| 80 | VK_P | Pキー |
| 81 | VK_Q | Qキー |
| 82 | VK_R | Rキー |
| 83 | VK_S | Sキー |
| 84 | VK_T | Tキー |
| 85 | VK_U | Uキー |
| 86 | VK_V | Vキー |
| 87 | VK_W | Wキー |
| 88 | VK_X | Xキー |
| 89 | VK_Y | Yキー |
| 90 | VK_Z | Zキー |
| 91 | VK_WIN | Windowsキー |
| 92 | VK_START | 右Windowsキー |
| 92 | VK_RWIN | 右Windowsキー |
| 93 | VK_APPS | アプリケーションキー （右クリックメニュー） |
| 95 | VK_SLEEP | Sleepキー |
| 96 | VK_NUMPAD0 | 0キー（テンキー） |
| 97 | VK_NUMPAD1 | 1キー（テンキー） |
| 98 | VK_NUMPAD2 | 2キー（テンキー） |
| 99 | VK_NUMPAD3 | 3キー（テンキー） |
| 100 | VK_NUMPAD4 | 4キー（テンキー） |
| 101 | VK_NUMPAD5 | 5キー（テンキー） |
| 102 | VK_NUMPAD6 | 6キー（テンキー） |
| 103 | VK_NUMPAD7 | 7キー（テンキー） |
| 104 | VK_NUMPAD8 | 8キー（テンキー） |
| 105 | VK_NUMPAD9 | 9キー（テンキー） |
| 106 | VK_MULTIPLY | *キー（テンキー） |
| 107 | VK_ADD | +キー（テンキー） |
| 108 | VK_SEPARATOR | separatorキー |
| 109 | VK_SUBTRACT | -キー（テンキー） |
| 110 | VK_DECIMAL | 小数点キー |
| 111 | VK_DIVIDE | /キー（テンキー） |
| 112 | VK_F1 | F1キー |
| 113 | VK_F2 | F2キー |
| 114 | VK_F3 | F3キー |
| 115 | VK_F4 | F4キー |
| 116 | VK_F5 | F5キー |
| 117 | VK_F6 | F6キー |
| 118 | VK_F7 | F7キー |
| 119 | VK_F8 | F8キー |
| 120 | VK_F9 | F9キー |
| 121 | VK_F10 | F10キー |
| 122 | VK_F11 | F11キー |
| 123 | VK_F12 | F12キー |
| 144 | VK_NUMLOCK | NumLockキー |
| 145 | VK_SCROLL | ScrollLockキー |
| 161 | VK_RSHIFT | 右Shiftキー |
| 163 | VK_RCTRL | 右Ctrlキー |
| 165 | VK_RALT | 右Altキー |
| 166 | VK_BROWSER_BACK | ブラウザ戻るキー |
| 167 | VK_BROWSER_FORWARD | ブラウザ進むキー |
| 168 | VK_BROWSER_REFRESH | ブラウザ更新キー |
| 169 | VK_BROWSER_STOP | ブラウザ停止キー |
| 170 | VK_BROWSER_SEARCH | ブラウザサーチキー |
| 171 | VK_BROWSER_FAVORITES | ブラウザお気に入りキー |
| 172 | VK_BROWSER_HOME | ブラウザホームキー |
| 173 | VK_VOLUME_MUTE | 音量をミュートにする |
| 174 | VK_VOLUME_DOWN | 音量を下げる |
| 175 | VK_VOLUME_UP | 音量を上げる |
| 176 | VK_MEDIA_NEXT_TRACK | メディア次トラックキー |
| 177 | VK_MEDIA_PREV_TRACK | メディア前トラックキー |
| 178 | VK_MEDIA_STOP | メディア停止キー |
| 179 | VK_MEDIA_PLAY_PAUSE | メディア再生キー/メディア一時停止キー |
| 180 | VK_LAUNCH_MAIL | メール起動キー |
| 181 | VK_LAUNCH_MEDIA_SELECT | メディア選択キー |
| 182 | VK_LAUNCH_APP1 | 起動キー1 |
| 183 | VK_LAUNCH_APP2 | 起動キー2 |
| 186 | VK_OEM_1 | OEM定義(;:*等)キー |
| 187 | VK_OEM_PLUS | OEM定義(;+等)キー |
| 188 | VK_OEM_COMMA | OEM定義(,<等)キー |
| 189 | VK_OEM_MINUS | OEM定義(-=等)キー |
| 190 | VK_OEM_PERIOD | OEM定義(.>等)キー |
| 191 | VK_OEM_2 | OEM定義(/?等)キー |
| 192 | VK_OEM_3 | OEM定義(~@`等)キー |
| 219 | VK_OEM_4 | OEM定義([{)キー |
| 220 | VK_OEM_5 | OEM定義(\|)キー |
| 221 | VK_OEM_6 | OEM定義(]})キー |
| 222 | VK_OEM_7 | OEM定義('"^~)キー |
| 223 | VK_OEM_8 | OEM定義キー |
| 233 | VK_OEM_RESET | OEM定義キー |
| 234 | VK_OEM_JUMP | OEM定義キー |
| 235 | VK_OEM_PA1 | OEM定義キー |
| 236 | VK_OEM_PA2 | OEM定義キー |
| 237 | VK_OEM_PA3 | OEM定義キー |
| 250 | VK_PLAY | |
| 251 | VK_ZOOM | |
| 901 | VK_RRETURN |
プログラム実行例
画像をクリップボードにコピーする
Alt+Sでマウスカーソル下のオブジェクトのスクリーンショット画像をクリップボードにコピーします。
使用関数
解説
アイドル時間を取得
最後にキーボードまたはマウスを操作してから経過した時間をミリ秒で取得します。
SETHOTKEY(VK_S, MOD_ALT, "imageToClipboard")
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
WHILE TRUE
SLEEP(0.01)
WEND
PROCEDURE imageToClipboard()
SAVEIMG( , GETID(GET_FROMPOINT_WIN))
FEND
//////////////////////////////////////////////////
// 【引数】
//
// 【戻り値】
//
//////////////////////////////////////////////////
PROCEDURE forceQuit()
EXITEXIT
FEND使用関数
マウスカーソル下のウィンドウの情報を吹き出しに表示
DEF_DLL GetTickCount(): Dword: kernel32
DEF_DLL GetLastInputInfo({DWORD, DWORD}): BOOL: user32
DIM t
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
WHILE TRUE
GetLastInputInfo(8, t)
FUKIDASI((GetTickCount() - t) + "ms")
SLEEP(0.01)
WEND
//////////////////////////////////////////////////
// 【引数】
//
// 【戻り値】
//
//////////////////////////////////////////////////
PROCEDURE forceQuit()
EXITEXIT
FEND使用関数
特定のキーを連打する
PUBLIC ttl, cls
SETHOTKEY(VK_ESC, , "forceQuit")
SETHOTKEY(VK_S, MOD_ALT, "output")
WHILE TRUE
ID = GETID(GET_FROMPOINT_WIN)
msg = ""
msg = msg + "ALT+Sでカーソル下のタイトルとクラス名を出力<#CR>"
msg = msg + "ESCで終了<#CR>"
msg = msg + "<#CR>"
ttl = STATUS(ID, ST_TITLE)
cls = STATUS(ID, ST_CLASS)
msg = msg + "タイトル：" + ttl + "<#CR>"
msg = msg + "クラス名：" + cls + "<#CR>"
msg = msg + "X座標：" + STATUS(ID, ST_X) + "<#CR>"
msg = msg + "Y座標：" + STATUS(ID, ST_Y) + "<#CR>"
msg = msg + "幅：" + STATUS(ID, ST_WIDTH) + "<#CR>"
msg = msg + "高さ：" + STATUS(ID, ST_HEIGHT) + "<#CR>"
msg = msg + "クライアントX座標：" + STATUS(ID, ST_CLX) + "<#CR>"
msg = msg + "クライアントY座標：" + STATUS(ID, ST_CLY) + "<#CR>"
msg = msg + "クライアント幅：" + STATUS(ID, ST_CLWIDTH) + "<#CR>"
msg = msg + "クライアント高さ：" + STATUS(ID, ST_CLHEIGHT) + "<#CR>"
msg = msg + "親ウィンドウID：" + STATUS(ID, ST_PARENT) + "<#CR>"
msg = msg + "アイコン状態：" + STATUS(ID, ST_ICON) + "<#CR>"
msg = msg + "最大化：" + STATUS(ID, ST_MAXIMIZED) + "<#CR>"
msg = msg + "表示状態：" + STATUS(ID, ST_VISIBLE) + "<#CR>"
msg = msg + "アクティブ状態：" + STATUS(ID, ST_ACTIVE) + "<#CR>"
msg = msg + "ビジー状態：" + STATUS(ID, ST_BUSY) + "<#CR>"
msg = msg + "有効ID：" + STATUS(ID, ST_ISID) + "<#CR>"
msg = msg + "64bit：" + STATUS(ID, ST_WIN64) + "<#CR>"
msg = msg + "EXEパス：" + STATUS(ID, ST_PATH) + "<#CR>"
msg = msg + "プロセスID：" + STATUS(ID, ST_PROCESS) + "<#CR>"
msg = msg + "モニター番号：" + STATUS(ID, ST_MONITOR) + "<#CR>"
FUKIDASI(msg)
SLEEP(0.01)
WEND
// 強制終了する
PROCEDURE forceQuit()
EXITEXIT
FEND
// カーソル下のウィンドウのタイトルとクラス名を出力
PROCEDURE output()
PRINT "GETID(<#DBL>" + ttl + "<#DBL>, <#DBL>" + cls + "<#DBL>)"
PRINT ttl
PRINT cls
PRINT "----------"
FEND使用関数
現在のカーソル位置を吹き出しに表示
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
SETHOTKEY(VK_SPACE, EMPTYPARAM, "toggle")
PUBLIC flg = FALSE
WHILE TRUE
DIM msg = "Spaceキーで切り替え<#CR>ESCキーで終了<#CR>"
IFB flg THEN
FUKIDASI(msg + "連打中")
KBD(VK_A, CLICK)
SLEEP(0.100)
ELSE
FUKIDASI(msg + "停止中")
ENDIF
WEND
PROCEDURE forceQuit()
EXITEXIT
FEND
PROCEDURE toggle()
flg = !flg
SLEEP(0.500)
FEND使用関数
プログラム実行時からの経過時間を表示（ESCで終了）
DEF_DLL GetCursorPos({long, long}): bool: user32
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
DIM x, y
WHILE TRUE
GetCursorPos(x, y)
FUKIDASI(x + ", " + y)
SLEEP(0.001)
WEND
PROCEDURE forceQuit()
EXITEXIT
FEND使用関数
メールの受信を検知（Outlook）
メールを受信したら日時を出力する。日時はメールの受信日時ではなくOutlookが受信を検知した日時。
SETHOTKEY(VK_ESC, , "forceQuit")
DIM t = GETTIME()
WHILE TRUE
FUKIDASI(GETTIME() - t)
SLEEP(0.001)
WEND
PROCEDURE forceQuit()
EXITEXIT
FEND使用関数
フラッシュ暗算
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
DIM Outlook = GETACTIVEOLEOBJ("Outlook.Application")
OLEEVENT(Outlook, "ApplicationEvents_11", "NewMailEx", "receivedMail")
WHILE TRUE
FUKIDASI("ESCで終了")
SLEEP(0.001)
WEND
PROCEDURE forceQuit()
EXITEXIT
FEND
PROCEDURE receivedMail()
PRINT text(now(), "yyyy/mm/dd hh:nn:ss")
FEND
//////////////////////////////////////////////////
// 【引数】
// interval : 加算する時間間隔を表す文字列式（yyyy：年、m：月、d：日、ww：週、h：時、n：分、s：秒）
// num : dateに加算する値。未来は正、過去は負で指定
// date : 時間間隔を加算する日付
// 【戻り値】
// 日時（date）に、指定した単位（interval）の時間（num）を加算して返します
//////////////////////////////////////////////////
FUNCTION dateAdd(interval, num, date)
DIM year, month, day, d
GETTIME(0, date)
DIM time = G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2
SELECT interval
CASE "yyyy"
d = (G_TIME_YY + num) + "/" + G_TIME_MM2 + "/" + G_TIME_DD2
IF time <> "00:00:00" THEN d = d + " " + time
CASE "m"
IFB num > 0 THEN
year = G_TIME_YY + INT((G_TIME_MM + num) / 12)
month = REPLACE(FORMAT(((G_TIME_MM + num) MOD 12), 2), " ", "0")
ELSE
year = G_TIME_YY + CEIL((G_TIME_MM + num) / 12 - 1)
month = REPLACE(FORMAT(G_TIME_MM - (ABS(num) MOD 12), 2), " ", "0")
ENDIF
IF month = "00" THEN month = 12
day = G_TIME_DD2
d = "" + year + month + day
IFB !isDate(d) THEN
d = year + "/" + month + "/" + "01"
d = getEndOfMonth(d)
ELSE
d = year + "/" + month + "/" + day
ENDIF
IF time <> "00:00:00" THEN d = d + " " + time
CASE "d"
t = GETTIME(num, date)
d = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + IIF(t MOD 86400, " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2, "")
CASE "ww"
t = GETTIME(num * 7, date)
d = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + IIF(t MOD 86400, " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2, "")
CASE "h"
t = GETTIME(num / 24, date)
d = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + IIF(t MOD 86400, " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2, "")
CASE "n"
t = GETTIME(num / 1440, date)
d = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + IIF(t MOD 86400, " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2, "")
CASE "s"
t = GETTIME(num / 86400, date)
d = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + IIF(t MOD 86400, " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2, "")
SELEND
RESULT = d
FEND
//////////////////////////////////////////////////
// 【引数】
// interval : 時間単位（yyyy︰年、q：四半期、m︰月、d︰日、w：週日、ww：週、h：時、n：分、s：秒）
// date1 : 日時1
// date2 : 日時2
// 【戻り値】
// date2からdate1を引いた時間間隔を求めます。
//////////////////////////////////////////////////
FUNCTION dateDiff(interval, date1, date2)
DIM y1, y2, m1, m2, d1, d2, d
SELECT interval
CASE "yyyy"
GETTIME(0, date1)
y1 = G_TIME_YY
GETTIME(0, date2)
y2 = G_TIME_YY
d = y2 - y1
CASE "q"
GETTIME(0, date1)
y1 = G_TIME_YY
m1 = G_TIME_MM
GETTIME(0, date2)
y2 = G_TIME_YY
m2 = G_TIME_MM
d = y2 * 4 + CEIL(m2/3) - (y1 * 4 + CEIL(m1/3))
CASE "m"
GETTIME(0, date1)
y1 = G_TIME_YY
m1 = G_TIME_MM
GETTIME(0, date2)
y2 = G_TIME_YY
m2 = G_TIME_MM
d = (y2 - y1) * 12 + m2 - m1
CASE "d"
d1 = GETTIME(0, date1)
d2 = GETTIME(0, date2)
d = (d2 - d1) / 86400
CASE "w"
d = INT(dateDiff("d", date1, date2) / 7)
CASE "ww"
date1 = dateAdd("d", -1 * getWeekday(date1), date1)
d = INT(dateDiff("d", date1, date2) / 7)
CASE "h"
d = dateDiff("d", date1, date2) * 24
CASE "n"
d = dateDiff("d", date1, date2) * 1440
CASE "s"
d = dateDiff("d", date1, date2) * 86400
SELEND
RESULT = d
FEND
//////////////////////////////////////////////////
// 【引数】
// arr : 最大公約数を求める数値を格納した配列
// 【戻り値】
// 最大公約数
//////////////////////////////////////////////////
FUNCTION GCD(arr[])
DIM c = LENGTH(arr)
DIM rem = arr[c-1] MOD arr[c-2]
IFB rem = 0 THEN
IFB LENGTH(arr) = 2 THEN
RESULT = arr[c-2]
EXIT
ENDIF
RESIZE(arr, c-2)
RESULT = GCD(arr)
EXIT
ENDIF
arr[c-1] = arr[c-2]
arr[c-2] = rem
RESULT = GCD(arr)
FEND
//////////////////////////////////////////////////
// 【引数】
// date : 日付（”YYYYMMDD” or “YYYY/MM/DD” or “YYYY-MM-DD” or “YYYYMMDDHHNNSS” or “YYYY/MM/DD HH:NN:SS”）
// m : 第一引数の指定日からプラスマイナスm月とする
// 【戻り値】
// dateからm月後の月末の日付
//////////////////////////////////////////////////
FUNCTION getEndOfMonth(date, m = 0)
date = dateAdd("m", m + 1, date)
GETTIME(0, date)
GETTIME(-G_TIME_DD, date)
RESULT = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2
FEND
//////////////////////////////////////////////////
// 【引数】
// date : （”YYYYMMDD” or “YYYY/MM/DD” or “YYYY-MM-DD” or “YYYYMMDDHHNNSS” or “YYYY/MM/DD HH:NN:SS”）
// 【戻り値】
// 曜日 （0：日曜…、6：土曜）
//////////////////////////////////////////////////
FUNCTION getWeekday(date)
GETTIME(0, date)
RESULT = G_TIME_WW
FEND
//////////////////////////////////////////////////
// 【引数】
// 数値 : GETTIMEで取得した曜日の番号（G_TIME_WW=0：日曜….6：土曜）
// フォーマット : 以下のアルファベットは数値で指定した対応する曜日に置き換えられます。（aaa : 日〜土、aaaa : 日曜日〜土曜日、ddd : Sun〜Sat、dddd : Sunday〜Saturday）
// 【戻り値】
// 数値をフォーマットした文字列を返します。
//////////////////////////////////////////////////
FUNCTION getWeekdayName(num, format = "aaa")
DIM re = CREATEOLEOBJ("VBScript.RegExp")
DIM aaa[] = "日", "月", "火", "水", "木", "金", "土";
DIM aaaa[] = "日曜日", "月曜日", "火曜日", "水曜日", "木曜日", "金曜日", "土曜日";
DIM ddd[] = "Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat";
DIM dddd[] = "Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday";
match = reExecute(format, "(a|d)+")
type = match.Item(0).Value
RESULT = reReplace(format, EVAL(type + "[" + num + "]"), type)
FEND
//////////////////////////////////////////////////
// 【引数】
// serial : 時間を表すシリアル値を指定
// 【戻り値】
// 例）0…00、0.5…12、1.0…24
//////////////////////////////////////////////////
FUNCTION Hour(serial)
RESULT = INT(serial * 24) MOD 24
FEND
//////////////////////////////////////////////////
// 【引数】
// expr : 評価する式
// truepart : 評価した式がTrueのときに返す値
// falsepart : 評価した式がFalseのときに返す値
// 【戻り値】
// truepart : 評価した式がTrueのとき、falsepart : 評価した式がFalseのとき
//////////////////////////////////////////////////
FUNCTION IIF(expr, truepart, falsepart)
IFB EVAL(expr) THEN
RESULT = truepart
ELSE
RESULT = falsepart
ENDIF
FEND
//////////////////////////////////////////////////
// 【引数】
// date : 存在するかを調べる日付文字列。YYYYMMDD or YYYY/MM/DD or YYYY-MM-DDのいずれかの形式。
// 【戻り値】
// TRUE : 日付として認識できる、FALSE : 日付として認識できない
//////////////////////////////////////////////////
FUNCTION isDate(date)
TRY
GETTIME(0, date)
RESULT = TRUE
EXCEPT
RESULT = FALSE
ENDTRY
FEND
//////////////////////////////////////////////////
// 【引数】
//
// 【戻り値】
// 現在の日時
//////////////////////////////////////////////////
FUNCTION now()
GETTIME()
DIM datetime = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2
RESULT = (GETTIME(0, datetime) - GETTIME(0, "1899/12/30")) / 86400
FEND
//////////////////////////////////////////////////
// 【引数】
// str : 正規表現による検索の対象となる文字列
// Pattern : 正規表現で使用するパターンを設定
// IgnoreCase : 大文字・小文字を区別しない場合はTrue、区別する場合はFalse
// Global : 文字列全体を検索する場合はTrue、しない場合はFalse
// 【戻り値】
// 正規表現で検索した結果をMatchesコレクションとして返します。
//////////////////////////////////////////////////
FUNCTION reExecute(str, Pattern, IgnoreCase = TRUE, Global = TRUE)
DIM re = CREATEOLEOBJ("VBScript.RegExp")
re.Pattern = Pattern
re.IgnoreCase = IgnoreCase
re.Global = Global
RESULT = re.Execute(str)
FEND
//////////////////////////////////////////////////
// 【引数】
// str1 : 置換される文字列
// str2 : 置換後の文字列
// Pattern : 置換する文字列のパターン
// IgnoreCase : 大文字・小文字を区別しない場合はTrue、区別する場合はFalse
// Global : 文字列全体を検索する場合はTrue、しない場合はFalse
// 【戻り値】
// 正規表現置換後の文字列
//////////////////////////////////////////////////
FUNCTION reReplace(str1, str2, Pattern, IgnoreCase = TRUE, Global = TRUE)
DIM re = CREATEOLEOBJ("VBScript.RegExp")
re.Pattern = Pattern
re.IgnoreCase = IgnoreCase
re.Global = Global
RESULT = re.Replace(str1, str2)
FEND
//////////////////////////////////////////////////
// 【引数】
// str : 正規表現による検索の対象となる文字列
// Pattern : 正規表現で使用するパターンを設定
// IgnoreCase : 大文字・小文字を区別しない場合はTrue、区別する場合はFalse
// Global : 文字列全体を検索する場合はTrue、しない場合はFalse
// 【戻り値】
// 正規表現にマッチするかどうか
//////////////////////////////////////////////////
FUNCTION reTest(str, Pattern, IgnoreCase = TRUE, Global = TRUE)
DIM re = CREATEOLEOBJ("VBScript.RegExp")
re.Pattern = Pattern
re.IgnoreCase = IgnoreCase
re.Global = Global
RESULT = re.Test(str)
FEND
//////////////////////////////////////////////////
// 【引数】
// inputs : 繰り返す文字列
// multiplier : inputsを繰り返す回数
// 【戻り値】
// inputsをmultiplier回を繰り返した文字列を返します
//////////////////////////////////////////////////
FUNCTION strRepeat(inputs, multiplier)
DIM res = ""
FOR n = 1 TO multiplier
res = res + inputs
NEXT
RESULT = res
FEND
//////////////////////////////////////////////////
// 【引数】
// serial : シリアル値
// format : フォーマット
// 【戻り値】
// 数値を表示書式に基づいて変換した文字列
//////////////////////////////////////////////////
FUNCTION text(serial, format, hour12 = FALSE)
HASHTBL startDate
startDate["明治"] = "1868/01/25"
startDate["大正"] = "1912/07/30"
startDate["昭和"] = "1926/12/25"
startDate["平成"] = "1989/01/08"
startDate["令和"] = "2019/05/01"
DIM baseDate = "1899/12/30"
SELECT TRUE
CASE reTest(format, "\[h+\]")
Matches = reExecute(format, "\[(h+)\]")
DIM hour = iif(hour12, Hour(serial) MOD 12, Hour(serial))
RESULT = text(hour, strRepeat("0", LENGTH(Matches.Item(0).SubMatches(0))))
CASE reTest(format, "^h+$")
Matches = reExecute(format, "^(h+)$")
hour = iif(hour12, Hour(serial) MOD 12, Hour(serial))
RESULT = text(hour MOD 24, strRepeat("0", LENGTH(Matches.Item(0).SubMatches(0))))
CASE reTest(format, "\[m+\]")
Matches = reExecute(format, "\[(m+)\]")
RESULT = text(serial * 1440, strRepeat("0", LENGTH(Matches.Item(0).SubMatches(0))))
CASE format = "m"
GETTIME(serial, baseDate)
RESULT = text(G_TIME_MM, "0")
CASE format = "mm"
GETTIME(serial, baseDate)
RESULT = G_TIME_MM2
CASE format = "n"
GETTIME(serial, baseDate)
RESULT = G_TIME_NN
CASE format = "nn"
GETTIME(serial, baseDate)
RESULT = G_TIME_NN2
CASE format = "s"
GETTIME(serial, baseDate)
RESULT = text(G_TIME_SS, "0")
CASE format = "ss"
GETTIME(serial, baseDate)
RESULT = G_TIME_SS2
CASE format = "yyyy"
GETTIME(serial, baseDate)
RESULT = G_TIME_YY4
CASE format = "yy"
GETTIME(serial, baseDate)
RESULT = COPY(G_TIME_YY4, 3, 2)
CASE format = "e"
SELECT TRUE
CASE dateDiff("d", startDate["令和"], text(serial, "yyyy/mm/dd")) >= 0
RESULT = text(serial, "yyyy") - 2018
CASE dateDiff("d", startDate["平成"], text(serial, "yyyy/mm/dd")) >= 0
RESULT = text(serial, "yyyy") - 1988
CASE dateDiff("d", startDate["昭和"], text(serial, "yyyy/mm/dd")) >= 0
RESULT = text(serial, "yyyy") - 1925
CASE dateDiff("d", startDate["大正"], text(serial, "yyyy/mm/dd")) >= 0
RESULT = text(serial, "yyyy") - 1911
CASE dateDiff("d", startDate["明治"], text(serial, "yyyy/mm/dd")) >= 0
RESULT = text(serial, "yyyy") - 1867
SELEND
CASE format = "ee"
SELECT TRUE
CASE dateDiff("d", startDate["令和"], text(serial, "yyyy/mm/dd")) >= 0
RESULT = text(text(serial, "yyyy") - 2018, "00")
CASE dateDiff("d", startDate["平成"], text(serial, "yyyy/mm/dd")) >= 0
RESULT = text(text(serial, "yyyy") - 1988, "00")
CASE dateDiff("d", startDate["昭和"], text(serial, "yyyy/mm/dd")) >= 0
RESULT = text(text(serial, "yyyy") - 1925, "00")
CASE dateDiff("d", startDate["大正"], text(serial, "yyyy/mm/dd")) >= 0
RESULT = text(text(serial, "yyyy") - 1911, "00")
CASE dateDiff("d", startDate["明治"], text(serial, "yyyy/mm/dd")) >= 0
RESULT = text(text(serial, "yyyy") - 1867, "00")
SELEND
CASE format = "g"
SELECT TRUE
CASE dateDiff("d", startDate["令和"], text(serial, "yyyy/mm/dd")) >= 0; RESULT = "R"
CASE dateDiff("d", startDate["平成"], text(serial, "yyyy/mm/dd")) >= 0; RESULT = "H"
CASE dateDiff("d", startDate["昭和"], text(serial, "yyyy/mm/dd")) >= 0; RESULT = "S"
CASE dateDiff("d", startDate["大正"], text(serial, "yyyy/mm/dd")) >= 0; RESULT = "T"
CASE dateDiff("d", startDate["明治"], text(serial, "yyyy/mm/dd")) >= 0; RESULT = "M"
SELEND
CASE format = "gg"
RESULT = COPY(text(serial, "ggg"), 1, 1)
CASE format = "ggg"
SELECT TRUE
CASE dateDiff("d", startDate["令和"], text(serial, "yyyy/mm/dd")) >= 0; RESULT = "令和"
CASE dateDiff("d", startDate["平成"], text(serial, "yyyy/mm/dd")) >= 0; RESULT = "平成"
CASE dateDiff("d", startDate["昭和"], text(serial, "yyyy/mm/dd")) >= 0; RESULT = "昭和"
CASE dateDiff("d", startDate["大正"], text(serial, "yyyy/mm/dd")) >= 0; RESULT = "大正"
CASE dateDiff("d", startDate["明治"], text(serial, "yyyy/mm/dd")) >= 0; RESULT = "明治"
SELEND
CASE format = "mmmmm"
RESULT = COPY(text(serial, "mmmm"), 1, 1)
CASE format = "mmmm"
DIM month[] = "January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November", "December"
RESULT = month[text(serial, "m") - 1]
CASE format = "mmm"
RESULT = COPY(text(serial, "mmmm"), 1, 3)
CASE format = "dd"
GETTIME(serial, baseDate)
RESULT = text(G_TIME_DD2, "00")
CASE format = "d"
GETTIME(serial, baseDate)
RESULT = text(G_TIME_DD, "0")
CASE reTest(format, "^[ad]{3,4}$")
Matches = reExecute(format, "([ad]{3,4})")
GETTIME(serial, baseDate)
RESULT = getWeekdayName(G_TIME_WW, Matches.Item(0).SubMatches(0))
CASE reTest(format, "(0+\.?0+)?%")
Matches = reExecute(format, "(0+\.?0+)?%")
RESULT = text(serial * 100, Matches.Item(0).SubMatches(0)) + "%"
CASE reTest(format, "^\[DBNum\d{1,4}\](.*?)$")
Matches = reExecute(format, "^\[DBNum(\d{1,4})\](.*?)$")
DIM value = VAL(Matches.Item(0).SubMatches(0))
DIM sss = text(serial, Matches.Item(0).SubMatches(1))
Matches = reExecute(sss, "(\D+)?(\d+)(\D+)?")
DIM res = ""
FOR m = 0 TO Matches.Count - 1
serial = Matches.Item(m).SubMatches(1)
SELECT value
CASE 1, 2
DIM n[][9] = "〇", "一", "二", "三", "四", "五", "六", "七", "八", "九", + _
"", "壱", "弐", "参", "四", "伍", "六", "七", "八", "九"
DIM a[][3] = "", "十", "百", "千", + _
"", "拾", "百", "阡"
DIM b[][3] = "", "万", "億", "兆", + _
"", "萬", "億", "兆"
DIM r = ""
DIM j = 0
type = value - 1
REPEAT
DIM str = ""
DIM n4 = serial MOD 10000
FOR i = LENGTH(n4) TO 1 STEP -1
s = COPY(n4, i, 1)
IFB s = 1 AND a[type][LENGTH(n4)-i] <> "" THEN
str = IIF(s, a[type][LENGTH(n4)-i], "") + str
ELSE
str = n[type][s] + IIF(s, a[type][LENGTH(n4)-i], "") + str
ENDIF
NEXT
IF str <> "" THEN r = str + b[type][j] + r
j = j + 1
serial = INT(serial / 10000)
UNTIL serial = 0
res = res + Matches.Item(m).SubMatches(0) + r + Matches.Item(m).SubMatches(2)
CASE 3
res = res + Matches.Item(m).SubMatches(0) + STRCONV(serial, SC_FULLWIDTH) + Matches.Item(m).SubMatches(2)
CASE 4
res = res + Matches.Item(m).SubMatches(0) + STRCONV(serial, SC_HALFWIDTH) + Matches.Item(m).SubMatches(2)
SELEND
NEXT
RESULT = res
CASE reTest(format, "^(.*?)(AM\/PM|am\/pm|A\/P|a\/p)(.*?)$")
Matches = reExecute(format, "^(.*?)(AM\/PM|am\/pm|A\/P|a\/p)(.*?)$")
DIM array = SPLIT(Matches.Item(0).SubMatches(1), "/")
ampm = array[IIF(serial - INT(serial) >= 0.5, 1, 0)]
hour12 = TRUE
res = ""
WITH Matches.Item(0)
res = text(serial, .SubMatches(0), hour12) + ampm + text(serial, .SubMatches(2), hour12)
ENDWITH
RESULT = res
CASE reTest(format, "([^ymdagehns]{0,})?(([ymdagehns])\3{0,})([^ymdagehns]+)?")
Matches = reExecute(format, "([^ymdagehns]{0,})?(([ymdagehns])\3{0,})([^ymdagehns]+)?")
FOR n = 0 TO Matches.Count - 1
IF n = 0 THEN res = Matches.Item(n).SubMatches(0)
NEXT
FOR n = 0 TO Matches.Count - 1
WITH Matches.Item(n)
res = res + text(serial, .SubMatches(1), hour12) + .SubMatches(3)
ENDWITH
NEXT
RESULT = res
CASE format = "0/0"
DIM separator = POS(".", serial)
DIM g = 0
IFB separator <> 0 THEN
DIM keta = LENGTH(serial)
DIM shift = POWER(10, keta - separator)
IFB shift >= POWER(10, 15) THEN
DIM position = 0
FOR i = 0 TO 14
IFB serial * POWER(10, i) - serial >= 1 THEN
position = i
BREAK
ENDIF
NEXT
tmp = serial * POWER(10, position)
FOR i = 1 TO 15
r = (tmp * POWER(10, i)) / serial - (tmp / serial)
a1 = tmp * POWER(10, i) - tmp
IF a1 = INT(a1) THEN BREAK
NEXT
DIM frac[] = a1, r
g = GCD(frac)
RESULT = (a1/g) + "/" + (r/g)
ELSE
DIM molecule = serial * shift // 分子
DIM denominator = shift // 分母
DIM nums[] = molecule, denominator
g = GCD(nums)
molecule = molecule / g
denominator = denominator / g
RESULT = molecule + "/" + denominator
ENDIF
ELSE
RESULT = serial + "/1"
ENDIF
CASE reTest(format, "(0+)\.?(0+)?") AND UBound(SPLIT(format, ".")) <= 1
Matches = reExecute(format, "(0+)\.?(0+)?")
len1 = LENGTH(Matches.Item(0).SubMatches(0))
len2 = LENGTH(Matches.Item(0).SubMatches(1))
DIM arr[] = LENGTH(INT(serial)), len1
IFB POS(".", format) THEN
RESULT = REPLACE(FORMAT(serial, CALCARRAY(arr, CALC_MAX) + len2 + 1, len2), " ", "0")
ELSE
RESULT = REPLACE(FORMAT(serial, CALCARRAY(arr, CALC_MAX)), " ", "0")
ENDIF
SELEND
FEND
//////////////////////////////////////////////////
// 【引数】
// arrayname : 上限値を求める配列の名前
// dimension : 返す次元を示す整数
// 【戻り値】
// 配列の上限値
//////////////////////////////////////////////////
FUNCTION UBound(arrayname[], dimension = 1)
RESULT = EVAL("RESIZE(arrayname" + strRepeat("[0]", dimension - 1) + ")")
FEND使用関数
解説
マウスカーソル下のスクロールバー情報を取得
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
DIM grades[] = "20級(初級)", "19級(初級)", "18級(初級)", "17級(初級)", "16級(初級)", "15級(初級)", "14級(初級)", "13級(初級)", "12級(初級)", "11級(初級)", _
"10級(中級)", "9級(中級)", "8級(中級)", "7級(中級)", "6級(中級)", "5級(中級)", "4級(中級)", "3級(中級)", "2級(中級)", "1級(中級)", _
"初段(上級)", "2段(上級)", "3段(上級)", "4段(上級)", "5段(上級)", "6段(上級)", "7段(上級)", "8段(上級)", "9段(上級)", "10段(上級)", _
"11段(超上級)", "12段(超上級)", "13段(超上級)", "14段(超上級)", "15段(超上級)", "16段(超上級)", "17段(超上級)", "18段(超上級)", "19段(超上級)", "20段(超上級)"
DIM keta[] = 1, 1, 1, 1, 1, 1, 1, 1, 2, 2, _
2, 2, 2, 2, 2, 2, 2, 2, 2, 2, _
2, 3, 3, 3, 3, 3, 3, 3, 3, 3, _
3, 3, 3, 3, 3, 3, 3, 3, 3, 3
DIM num[] = 3, 3, 5, 8, 10, 12, 15, 20, 10, 15, _
2, 3, 4, 5, 6, 7, 8, 10, 12, 15, _
15, 4, 6, 8, 10, 12, 15, 15, 15, 15, _
15, 15, 15, 15, 15, 15, 15, 15, 15, 15
DIM time[] = 5, 5, 7, 10, 12, 15, 15, 15, 10, 15, _
4, 6, 7, 8, 9, 10, 11, 12, 12, 13, _
10, 4, 5, 6, 7, 8, 8, 6, 4.5, 3, _
2.8, 2.6, 2.4, 2.2, 2.0, 1.9, 1.8, 1.7, 1.6, 1.5
DIM grade = SLCTBOX(SLCT_CMB OR SLCT_NUM, 60, "レベルを選択", grades)
DIM sum = 0
DIM fontsize = 80
DIM fontname = "abacus2"
DIM fontcolor = $00aa00
DIM bgcolor = 1
FOR i = 1 TO num[grade]
DIM n = POWER(10, keta[grade] - 1) + RANDOM(POWER(10, keta[grade]) - POWER(10, keta[grade] - 1))
sum = sum + n
DIM msg = " " + n + " "
FUKIDASI(msg, G_SCREEN_W, G_SCREEN_H,, fontsize, fontname, fontcolor, bgcolor)
DIM ID = GETID(GET_FUKIDASI_WIN)
FUKIDASI(msg, (STATUS(ID, ST_X) - STATUS(ID, ST_WIDTH))/2, (STATUS(ID, ST_Y) - STATUS(ID, ST_HEIGHT))/2,, fontsize, fontname, fontcolor, bgcolor)
SOUND("BEEP")
SLEEP(time[grade])
FUKIDASI()
NEXT
DIM ans = INPUT("答えは？")
IFB ans = sum THEN
MSGBOX("正解です！(ans." + sum + ")")
ELSE
MSGBOX("残念でした、正解は " + sum + " です。")
ENDIF
PROCEDURE forceQuit()
EXITEXIT
FEND結果
[1]
値： 28
最小値： 0 最大値： 65
移動量： 12 表示方向： 1
X座標： 0 Y座標： 56
----------
[2]
値： 0
最小値： 0 最大値： 15
移動量： 11 表示方向： 1
X座標： 393 Y座標： 56
----------
[3]
値： 17
最小値： 0 最大値： 486
移動量： 450 表示方向： 0
X座標： 393 Y座標： 56
----------
[4]
値： 59
最小値： 0 最大値： 63
移動量： 5 表示方向： 1
X座標： 0 Y座標： 330
----------使用関数
Yahoo!ファイナンスから米ドル・ユーロ・豪ドルのレートを取得
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
WHILE TRUE
DIM ID = GETID(GET_FROMPOINT_WIN)
DIM str = ""
DIM i = 1
WHILE GETSLIDER(ID, i, SLD_POS) <> ERR_VALUE
str = str + "[" + i + "]<#CR>"
str = str + "値：" + GETSLIDER(ID, i, SLD_POS) + "<#CR>"
str = str + "最小値：" + GETSLIDER(ID, i, SLD_MIN) + "<#TAB>"
str = str + "最大値：" + GETSLIDER(ID, i, SLD_MAX) + "<#CR>"
str = str + "移動量：" + GETSLIDER(ID, i, SLD_PAGE) + "<#TAB>"
str = str + "表示方向：" + GETSLIDER(ID, i, SLD_BAR) + "<#CR>"
str = str + "X座標：" + GETSLIDER(ID, i, SLD_X) + "<#TAB>"
str = str + "Y座標：" + GETSLIDER(ID, i, SLD_Y) + "<#CR>"
str = str + "----------<#CR>"
i = i + 1
WEND
FUKIDASI(TRIM(str))
WEND
//////////////////////////////////////////////////
// 【引数】
//
// 【戻り値】
//
//////////////////////////////////////////////////
PROCEDURE forceQuit()
EXITEXIT
FEND使用関数
ファイルを開いているプロセスを調べる
IE = CREATEOLEOBJ("InternetExplorer.Application")
IE.Visible = TRUE
IE.Navigate("https://info.finance.yahoo.co.jp/fx/")
BusyWait(IE)
// ループを抜ける用のフラグ
PUBLIC flg = FALSE
// ESCキーを入力でloopBreak関数を実行
SETHOTKEY(VK_ESC, , "loopBreak")
REPEAT
usd = IE.document.getElementById("USDJPY_top_bid").innerText
eur = IE.document.getElementById("EURJPY_top_bid").innerText
aud = IE.document.getElementById("AUDJPY_top_bid").innerText
msg = "米ドル/円<#TAB>" + usd + "<#CR>" + _
"ユーロ/円<#TAB>" + eur + "<#CR>" + _
"豪ドル/円<#TAB>" + aud + "<#CR>" + _
"ESCで終了"
FUKIDASI(msg)
SLEEP(0.01)
UNTIL flg = TRUE
IE.Quit
PROCEDURE loopBreak()
flg = TRUE
FEND
//////////////////////////////////////////////////
// 【引数】
// array : 要素を追加する配列（参照引数）
// values : 追加する要素をvalue1から指定
// 【戻り値】
// 処理後の配列の要素の数
//////////////////////////////////////////////////
FUNCTION arrayPush(var array[], value1 = EMPTY, value2 = EMPTY, value3 = EMPTY, value4 = EMPTY, value5 = EMPTY, value6 = EMPTY, value7 = EMPTY, value8 = EMPTY, value9 = EMPTY, value10 = EMPTY, value11 = EMPTY, value12 = EMPTY, value13 = EMPTY, value14 = EMPTY, value15 = EMPTY, value16 = EMPTY)
DIM i = 1
WHILE EVAL("value" + i) <> EMPTY
DIM res = RESIZE(array, UBound(array) + 1)
array[res] = EVAL("value" + i)
i = i + 1
WEND
RESULT = LENGTH(array)
FEND
//////////////////////////////////////////////////
// 【引数】
// needle : 検索する値
// haystack : 配列
// 【戻り値】
// needleが見つかった場合に配列のキー
//////////////////////////////////////////////////
FUNCTION arraySearch(needle, haystack[])
DIM i = 0
FOR item IN haystack
IFB item = needle THEN
RESULT = i
EXIT
ENDIF
i = i + 1
NEXT
FEND
//////////////////////////////////////////////////
// 【引数】
// IE : IEオブジェクト
// 【戻り値】
//
//////////////////////////////////////////////////
PROCEDURE BusyWait(Var IE)
SLEEP(0.500)
DIM t = GETTIME()
TRY
REPEAT
DIM tm = GETTIME() - t
FUKIDASI("BusyWait：" + tm)
SLEEP(0.010)
IF tm >= 60 THEN BREAK
UNTIL !IE.Busy AND IE.readyState = 4
EXCEPT
IE = getIEObj(-1)
PRINT IE.document.URL + " のIEオブジェクトを取得しました。"
BusyWait(IE)
ENDTRY
FUKIDASI()
FEND
//////////////////////////////////////////////////
// 【引数】
// 文字列 or 数値 : 取得したい<a href="https://uwsc.jp/com/ie/" >InternetExplorer オブジェクト</a>のタイトル・URLもしくは数値を指定
// 完全一致フラグ : （TRUE : 文字列が完全一致したものを取得、FALSE : 文字列の一部を含むものを取得）
// 【戻り値】
// 条件に一致する<a href="https://uwsc.jp/com/ie" >InternetExplorer</a>
//////////////////////////////////////////////////
FUNCTION getIEObj(str, flg = FALSE)
DIM Shell = CREATEOLEOBJ("Shell.Application")
DIM ShellWindows = Shell.Windows
DIM IE[-1]
FOR i = 0 TO ShellWindows.Count - 1
TRY
IFB ShellWindows.Item(i).Name = "Internet Explorer" THEN
arrayPush(IE, ShellWindows.Item(i))
ENDIF
EXCEPT
ENDTRY
NEXT
SELECT CHKNUM(str)
CASE TRUE
IFB str = 0 THEN
RESULT = LENGTH(IE)
ELSE
IF str < 0 THEN str = str + LENGTH(IE) + 1
TRY
RESULT = IE[str-1]
EXCEPT
RESULT = ERR_VALUE
ENDTRY
ENDIF
CASE FALSE
DIM pattern = IIF(flg, "^" + str + "$", str)
DIM titleList = SLICE(IE)
FOR i = 0 TO UBound(titleList)
titleList[i] = titleList[i].Document.title
NEXT
DIM urlList = SLICE(IE)
FOR i = 0 TO UBound(urlList)
urlList[i] = urlList[i].Document.URL
NEXT
DIM num = ERR_VALUE
SELECT TRUE
CASE pregGrep(pattern, titleList) <> FALSE; num = arraySearch(pregGrep(pattern, titleList)[0], titleList)
CASE pregGrep(pattern, urlList) <> FALSE; num = arraySearch(pregGrep(pattern, urlList)[0], urlList)
SELEND
TRY
RESULT = IE[num]
EXCEPT
RESULT = ERR_VALUE
ENDTRY
SELEND
FEND
//////////////////////////////////////////////////
// 【引数】
// expr : 評価する式
// truepart : 評価した式がTrueのときに返す値
// falsepart : 評価した式がFalseのときに返す値
// 【戻り値】
// truepart : 評価した式がTrueのとき、falsepart : 評価した式がFalseのとき
//////////////////////////////////////////////////
FUNCTION IIF(expr, truepart, falsepart)
IFB EVAL(expr) THEN
RESULT = truepart
ELSE
RESULT = falsepart
ENDIF
FEND
//////////////////////////////////////////////////
// 【引数】
// pattern : 検索するパターンを表す文字列
// array : 検索される配列
// 【戻り値】
//
//////////////////////////////////////////////////
FUNCTION pregGrep(pattern, array[], flags = 0)
DIM res[-1]
FOR item IN array
IF reTest(item, pattern) THEN arrayPush(res, item)
NEXT
RESULT = SLICE(res)
FEND
//////////////////////////////////////////////////
// 【引数】
// str : 正規表現による検索の対象となる文字列
// Pattern : 正規表現で使用するパターンを設定
// IgnoreCase : 大文字・小文字を区別しない場合はTrue、区別する場合はFalse
// Global : 文字列全体を検索する場合はTrue、しない場合はFalse
// 【戻り値】
// 正規表現にマッチするかどうか
//////////////////////////////////////////////////
FUNCTION reTest(str, Pattern, IgnoreCase = TRUE, Global = TRUE)
DIM re = CREATEOLEOBJ("VBScript.RegExp")
re.Pattern = Pattern
re.IgnoreCase = IgnoreCase
re.Global = Global
RESULT = re.Test(str)
FEND
//////////////////////////////////////////////////
// 【引数】
// inputs : 繰り返す文字列
// multiplier : inputsを繰り返す回数
// 【戻り値】
// inputsをmultiplier回を繰り返した文字列を返します
//////////////////////////////////////////////////
FUNCTION strRepeat(inputs, multiplier)
DIM res = ""
FOR n = 1 TO multiplier
res = res + inputs
NEXT
RESULT = res
FEND
//////////////////////////////////////////////////
// 【引数】
// arrayname : 上限値を求める配列の名前
// dimension : 返す次元を示す整数
// 【戻り値】
// 配列の上限値
//////////////////////////////////////////////////
FUNCTION UBound(arrayname[], dimension = 1)
RESULT = EVAL("RESIZE(arrayname" + strRepeat("[0]", dimension - 1) + ")")
FEND使用関数
解説
キーボードからの入力を1文字ずつずらす
キーからのA→B、B→C、…のように1文字後ろにずらします。
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
CONST TemporaryFolder = 2
DIM FSO = CREATEOLEOBJ("Scripting.FileSystemObject")
WITH FSO
DIM Folder = .GetSpecialFolder(TemporaryFolder)
DIM folderspec = Folder.Path
DIM filename = .GetTempName
DIM path = .BuildPath(folderspec, filename)
ENDWITH
DIM Shell = CREATEOLEOBJ("Shell.Application")
Shell.FileRun()
DIM ID = GETID("ファイル名を指定して実行", "#32770")
SENDSTR(ID, "cmd /c openfiles /query /fo CSV > " + path)
CLKITEM(ID, "OK", CLK_BTN)
SLEEP(0.500)
REPEAT
SLEEP(0.100)
UNTIL GETID("C:\WINDOWS\system32\cmd.exe", "ConsoleWindowClass") = -1
DIM FID = FOPEN(path, F_READ)
TRY
DIM ID2 = GETID("使用中", "OperationStatusWindow")
GETITEM(ID2, ITM_ACCTXT, 1)
DIM str = ALL_ITEM_LIST[1]
DIM sep = IIF(POS("フォルダー", STATUS(ID2, ST_TITLE)) <> 0, "\", "")
DIM msg = "■" + str + "<#CR>"
FOR r = 5 TO FGET(FID, F_LINECOUNT)
IF POS("\" + str + sep, FGET(FID, r, 3)) <> 0 THEN
msg = msg + "ID：" + FGET(FID, r, 1) + ", プロセス名：" + FGET(FID, r, 2) + "<#CR>"
ENDIF
NEXT
FCLOSE(FID)
REPEAT
FUKIDASI(TRIM(msg))
SLEEP(0.100)
UNTIL GETID("使用中", "OperationStatusWindow") = -1
FINALLY
FSO.DeleteFile(path)
ENDTRY
//////////////////////////////////////////////////
// 【引数】
//
// 【戻り値】
//
//////////////////////////////////////////////////
PROCEDURE forceQuit()
EXITEXIT
FEND
//////////////////////////////////////////////////
// 【引数】
// expr : 評価する式
// truepart : 評価した式がTrueのときに返す値
// falsepart : 評価した式がFalseのときに返す値
// 【戻り値】
// truepart : 評価した式がTrueのとき、falsepart : 評価した式がFalseのとき
//////////////////////////////////////////////////
FUNCTION IIF(expr, truepart, falsepart)
IFB EVAL(expr) THEN
RESULT = truepart
ELSE
RESULT = falsepart
ENDIF
FEND使用関数
マウス位置の色を取得
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
PUBLIC array[-1]
FOR key = VK_A TO VK_Z
arrayPush(array, key)
NEXT
PUBLIC rotate
rotate = arrayRotate(array, 1)
PUBLIC key
FOR key = VK_A TO VK_Z
SETHOTKEY(key,, "keyChange")
SETHOTKEY(key, MOD_SHIFT, "keyChange")
NEXT
WHILE TRUE
FUKIDASI("キー割り当て変更中。ESCで終了")
SLEEP(0.001)
WEND
PROCEDURE keyChange()
DIM vk = rotate[arraySearch(HOTKEY_VK, array)]
IFB HOTKEY_MOD = 4 THEN
vk = STRCONV(vk, SC_UPPERCASE)
ENDIF
KBD(vk)
FEND
//////////////////////////////////////////////////
// 【引数】
// array : 一次元配列。参照引数。
// callback : コールバック関数。callback内で配列の値は「%val%」で使うことができます。
// 【戻り値】
// callback関数によりフィルタ処理が行われたarrayの全ての要素を含む配列を返します。
//////////////////////////////////////////////////
PROCEDURE arrayFilter(var array[], callback)
DIM n = 0
DIM tmp[-1]
FOR %val% IN array
IFB EVAL(callback) THEN
RESIZE(tmp, n)
tmp[n] = %val%
n = n + 1
ENDIF
NEXT
RESIZE(array, RESIZE(tmp))
FOR n = 0 TO RESIZE(tmp)
array[n] = tmp[n]
NEXT
FEND
//////////////////////////////////////////////////
// 【引数】
// arr : 追加される配列（参照引数）
// tmp : 追加する配列
// 【戻り値】
// 追加した後の配列の要素数
//////////////////////////////////////////////////
FUNCTION arrayMerge(Var arr[], tmp[])
FOR n = 0 TO UBound(tmp)
arrayPush(arr, tmp[n])
NEXT
RESULT = UBound(arr)
FEND
//////////////////////////////////////////////////
// 【引数】
// array : 要素を追加する配列（参照引数）
// values : 追加する要素をvalue1から指定
// 【戻り値】
// 処理後の配列の要素の数
//////////////////////////////////////////////////
FUNCTION arrayPush(var array[], value1 = EMPTY, value2 = EMPTY, value3 = EMPTY, value4 = EMPTY, value5 = EMPTY, value6 = EMPTY, value7 = EMPTY, value8 = EMPTY, value9 = EMPTY, value10 = EMPTY, value11 = EMPTY, value12 = EMPTY, value13 = EMPTY, value14 = EMPTY, value15 = EMPTY, value16 = EMPTY)
DIM i = 1
WHILE EVAL("value" + i) <> EMPTY
DIM res = RESIZE(array, UBound(array) + 1)
array[res] = EVAL("value" + i)
i = i + 1
WEND
RESULT = LENGTH(array)
FEND
//////////////////////////////////////////////////
// 【引数】
// array : 配列
// shift : シフトする要素数。正の数で末尾方向。負の数で先頭方向。
// 【戻り値】
//
//////////////////////////////////////////////////
FUNCTION arrayRotate(array[], shift)
IF shift < 0 THEN shift = LENGTH(array) + shift
DIM array1 = arraySlice(array, shift)
DIM array2 = arraySlice(array, 0, shift)
arrayMerge(array1, array2)
RESULT = array1
FEND
//////////////////////////////////////////////////
// 【引数】
// needle : 検索する値
// haystack : 配列
// 【戻り値】
// needleが見つかった場合に配列のキー
//////////////////////////////////////////////////
FUNCTION arraySearch(needle, haystack[])
DIM i = 0
FOR item IN haystack
IFB item = needle THEN
RESULT = i
EXIT
ENDIF
i = i + 1
NEXT
FEND
//////////////////////////////////////////////////
// 【引数】
// array : 配列
// offset : 配列の位置。負の値の場合、配列の後ろから
// length : lengthが省略された場合は末尾まで。lengthが正の数ならば、offsetからlengthの数だけ要素を取得。lengthが負の数ならば、末尾からlengthだけ切り捨てる。
// 【戻り値】
//
//////////////////////////////////////////////////
FUNCTION arraySlice(array[], offset, length = NULL)
SELECT TRUE
CASE offset > 0
SHIFTARRAY(array, -1 * offset)
IF length = NULL THEN length = LENGTH(array) - offset
RESIZE(array, length - 1)
CASE offset < 0
SHIFTARRAY(array, ABS(offset) - LENGTH(array))
RESIZE(array, LENGTH(array) - ABS(offset))
arrayFilter(array, "%val% <> EMPTY")
IF length < 0 THEN RESIZE(array, RESIZE(array) + length)
CASE offset = 0
IF length = NULL THEN length = LENGTH(array)
RESIZE(array, length - 1)
SELEND
RESULT = SLICE(array)
FEND
//////////////////////////////////////////////////
// 【引数】
//
// 【戻り値】
//
//////////////////////////////////////////////////
PROCEDURE forceQuit()
EXITEXIT
FEND
//////////////////////////////////////////////////
// 【引数】
// inputs : 繰り返す文字列
// multiplier : inputsを繰り返す回数
// 【戻り値】
// inputsをmultiplier回を繰り返した文字列を返します
//////////////////////////////////////////////////
FUNCTION strRepeat(inputs, multiplier)
DIM res = ""
FOR n = 1 TO multiplier
res = res + inputs
NEXT
RESULT = res
FEND
//////////////////////////////////////////////////
// 【引数】
// arrayname : 上限値を求める配列の名前
// dimension : 返す次元を示す整数
// 【戻り値】
// 配列の上限値
//////////////////////////////////////////////////
FUNCTION UBound(arrayname[], dimension = 1)
RESULT = EVAL("RESIZE(arrayname" + strRepeat("[0]", dimension - 1) + ")")
FEND使用関数
解説
キャレット（カーソル）位置を取得
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
WHILE TRUE
DIM c = PEEKCOLOR(G_MOUSE_X, G_MOUSE_Y)
DIM r = c AND $FF
DIM g = (c AND $FF00) / $100
DIM b = (c AND $FF0000) / $10000
FUKIDASI("赤<#TAB>" + r + "<#CR>緑<#TAB>" + g + "<#CR>青<#TAB>" + b)
SLEEP(0.001)
WEND
//////////////////////////////////////////////////
// 【引数】
//
// 【戻り値】
//
//////////////////////////////////////////////////
PROCEDURE forceQuit()
EXITEXIT
FEND使用関数
CLKITEMで操作できる項目を取得
DEF_DLL GetCaretPos({long, long}): bool: user32
SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
DIM x, y
WHILE TRUE
GetCaretPos(x, y)
FUKIDASI(x + ", " + y)
SLEEP(0.010)
WEND
//////////////////////////////////////////////////
// 【引数】
//
// 【戻り値】
//
//////////////////////////////////////////////////
PROCEDURE forceQuit()
EXITEXIT
FEND使用関数
解説
この記事は役に立ちましたか？
ご協力ありがとうございます。
関連記事
- SCKEY関数 (スクリプト関数)
- ショートカットキーを実行します。
- GETKEYSTATE関数 (スクリプト関数)
- キーコードの状態を取得します。