1. ID
2. 仮想キー
3. ショートカットキー

ショートカットキーを実行します。

構文

1. void = SCKEY( ID, キー, キー, キー, キー, ... )

引数

ID （Integer）必須

Windowを識別するID。指定するウィンドウがない場合には IDに0を指定。

キー （#sckey）必須

アルファベット１文字もしくは仮想キー(VK_*)

動作としてVK_SHIFT,VK_CTRL,VK_ALT,VK_WINのキー指定は押し下げ状態のまま処理する

戻り値

キーコードの調べ方

入力したキーの仮想キーコードをリアルタイムで調べることのできるフリーソフトウェアのKeymillを使うと簡単に取得できます。

仮想キーコード

SCKEY関数からKBD関数への書き換え

SCKEY関数はショートカットキーを実行する関数、KBD関数はキーボードの操作を行う関数で用途は違いますが、SCKEY関数のショートカットキーの入力というのはキーボードの操作を行っていることと同じなのでKBD関数に書き換えることができます。

修飾子キーが1つ

SCKEY関数の修飾子キーをmodiferKey、組み合わせるキーをkeyとします。

SCKEY(ID, modiferKey, key)

修飾子キーが1つの場合はmodiferKeyをDOWN処理のままkeyをクリック、modiferKeyをUP処理を行い、KBD関数で書き換えると以下のようになります。

CTRLWIN(ID, ACTIVATE)

KBD(modiferKey, DOWN)
KBD(key, CLICK)
KBD(modiferKey, UP)

修飾子キーが2つ以上

まずSCKEY関数の処理は、第1引数のウィンドウをアクティブにし第2引数以降のキーを順番に押していく処理を行っています。修飾子キーをmodiferKey、その他の組み合わせるキーをkeyとしSCKEY関数は以下のように記述したとします。

SCKEY(ID, modiferKey1, modiferKey2, key)

これをKBD関数で記述した場合は以下のようになります。修飾子キーは押し下げ状態のまま処理が行われるのでmodiferKey1、modiferKey2はDOWN状態を保持し、keyはクリック、SCKEY関数の最後の引数までキーの処理が終わったら修飾子キーを最後に押し下げたキーから順にUPにしていきます。

CTRLWIN(ID, ACTIVATE)

KBD(modifierKey1, DOWN)
KBD(modifierKey2, DOWN)
KBD(key, CLICK)
KBD(modifierKey2, UP)
KBD(modifierKey1, UP)

具体的にタスクマネージャーを起動するショートカットキーCtrl＋Shift＋Escを例として示します。

まずSCKEY関数で書くと以下のようになります。

SCKEY(0, VK_CTRL, VK_SHIFT, VK_ESC)

これをKBD関数で書き換えると、まず第2引数のCtrlは修飾子キーなので押し下げたままにし、第3引数のShiftも修飾子キーなので押し下げたままにします。第4引数のEscは修飾子キーではないのでクリック処理を行います。

最後の引数まできたので、押し下げたままの修飾子キーを離していきます。

これらの処理をKBD関数で置き換えて記述すると以下のようになります。

KBD(VK_CTRL, DOWN)
KBD(VK_SHIFT, DOWN)
KBD(VK_ESC, CLICK)
KBD(VK_SHIFT, UP)
KBD(VK_CTRL, UP)

3つ以上の場合も処理は同じです。

SCKEY(ID, modiferKey1, modiferKey2, modiferKey3, modiferKey4, key)

CTRLWIN(ID, ACTIVATE)

KBD(modifierKey1, DOWN)
KBD(modifierKey2, DOWN)
KBD(modifierKey3, DOWN)
KBD(modifierKey4, DOWN)
KBD(key, CLICK)
KBD(modifierKey4, UP)
KBD(modifierKey3, UP)
KBD(modifierKey2, UP)
KBD(modifierKey1, UP)

使い方

デスクトップを表示するショートカットキー＋Dを実行します。

特定のウィンドウに対して実行するわけではないので第1引数は0、第2引数以降に実行するショートカットキーの仮想キーコードを記述します。はVK_WIN、DはVK_Dなので以下のようになります。

SCKEY(0, VK_WIN, VK_D)

このとき注意が必要なのが、第2引数以降ではまず修飾子キー（Ctrl、Shift、Alt、）から指定していくということです。

以下のように修飾子キーより先に組み合わせるキーを記述すると、ショートカットキーが上手く動作しません。具体的にはD、が順にクリックされるので、テキストが入力できる状態であればそこにDと入力されたあとスタートメニューが表示されると思います。

SCKEY(0, VK_D, VK_WIN)

SCKEY関数のキーに指定できる引数の数は35個（IDの引数を含めると36個）までです。

音量を調整

GETITEM関数で現在の音量を取得し、targetに指定された音量になるように調整します。以下の例では音量が30になるように調整します。

DIM target = 30

WHILE getVolume() > target
	KBD(VK_VOLUME_DOWN)
WEND

WHILE getVolume() < target
	KBD(VK_VOLUME_UP)
WEND

FUNCTION getVolume()
	GETITEM(GETID("", "Shell_TrayWnd"), ITM_TOOLBAR)
	FOR item IN ALL_ITEM_LIST
		IFB POS("スピーカー: ", item) <> 0 THEN
			DIM volume = REPLACE(REPLACE(item, "スピーカー: ", ""), "%", "")
			BREAK
		ENDIF
	NEXT

	IF volume = "ミュート" THEN volume = 0
	volume = VAL(volume)
	RESULT = volume
FEND

プログラム実行例

アクティブウィンドウのスクリーンショットを撮る

クリップボードにスクリーンショットがコピーされます。

SCKEY(GETID(GET_ACTIVE_WIN), VK_ALT, VK_SNAPSHOT)

メモ帳に本文を入力し[名前を付けて保存]ダイアログボックスを開いて保存する

DIM FSO = CREATEOLEOBJ("Scripting.FileSystemObject")
DIM path = "D:\Desktop\sample.txt"
DIM folderspec = FSO.GetParentFolderName(path)
DIM filename = FSO.GetFileName(path)

EXEC("notepad")
DIM ID = GETID("メモ帳", "Notepad")
SENDSTR(ID, "内容", 0)
CLKITEM(ID, "ファイル\名前を付けて保存", CLK_MENU)

IFB FSO.FolderExists(folderspec) THEN
	DIM ID2 = GETID("名前を付けて保存", "#32770")

	CTRLWIN(ID2, ACTIVATE)
	SLEEP(0.500)

	SCKEY(ID2, VK_F4)
	SENDSTR(ID2, folderspec, 1, TRUE)
	SCKEY(ID2, VK_RETURN)
	SLEEP(0.500)

	SCKEY(ID2, VK_ALT, VK_N)
	SENDSTR(ID2, filename, 1, TRUE)
	SLEEP(0.500)

	CLKITEM(ID, "保存", ITM_BTN)
ELSE
	PRINT "フォルダが存在しません。"
ENDIF

仮想キーで文章を入力

DIM ID = EXEC("notepad")

CTRLWIN(ID, ACTIVATE)

SCKEY(ID, VK_SHIFT, VK_T)
SCKEY(ID, VK_H, VK_I, VK_S, VK_SPACE, VK_I, VK_S, VK_SPACE, VK_A, VK_SPACE, VK_P, VK_E, VK_N, VK_OEM_PERIOD)

結果

プレーンテキスト

This is a pen.

CopyThis is a pen.

使用関数

EXEC関数(1)

CTRLWIN関数(3)

SCKEY関数(5-6)

設定画面を表示する

＋Iを実行し、設定画面を起動します。

UWSC

SCKEY(0, VK_WIN, VK_I)

CopySCKEY(0, VK_WIN, VK_I)

使用関数

SCKEY関数(1)

仮想デスクトップを追加する

＋Ctrl＋Dを実行し、仮想デスクトップを起動します。

UWSC

SCKEY(0, VK_WIN, VK_CTRL, VK_D)

CopySCKEY(0, VK_WIN, VK_CTRL, VK_D)

使用関数

SCKEY関数(1)

エクスプローラーを起動

＋Eを実行し、エクスプローラーを起動します。

UWSC

SCKEY(0, VK_WIN, VK_E)

CopySCKEY(0, VK_WIN, VK_E)

使用関数

SCKEY関数(1)

タスクバーアプリを起動

タスクバーにあるアプリは「Win＋数字」で起動することができます。数字は1〜9（1〜9番目）と0（10番目）。以下は＋1を実行し、タスクバーの左から1番目のアプリを起動します。

UWSC

SCKEY(0, VK_WIN, VK_1)

CopySCKEY(0, VK_WIN, VK_1)

使用関数

SCKEY関数(1)

アクティブウィンドウを最大化

＋↑を実行し、アクティブウィンドウを最大化します。

UWSC

SCKEY(0, VK_WIN, VK_UP)

CopySCKEY(0, VK_WIN, VK_UP)

使用関数

SCKEY関数(1)

アクティブウィンドウを最小化

＋↓を実行し、アクティブウィンドウを最小化します。

UWSC

SCKEY(0, VK_WIN, VK_DOWN)

CopySCKEY(0, VK_WIN, VK_DOWN)

使用関数

SCKEY関数(1)

指定範囲のスクリーンショットを撮る

＋Shift＋Sを実行し、指定範囲のスクリーンショットを撮ります。

UWSC

SCKEY(0, VK_WIN, VK_SHIFT, VK_S)

CopySCKEY(0, VK_WIN, VK_SHIFT, VK_S)

使用関数

SCKEY関数(1)

クリップボードを表示

＋Vを実行し、クリップボードを表示します。

UWSC

SCKEY(0, VK_WIN, VK_V)

CopySCKEY(0, VK_WIN, VK_V)

使用関数

SCKEY関数(1)

マルチディスプレイ出力モードの切り替え

＋Pを実行し、マルチディスプレイ出力モードの切り替え画面を表示します。

UWSC

SCKEY(0, VK_WIN, VK_P)

CopySCKEY(0, VK_WIN, VK_P)

使用関数

SCKEY関数(1)

メモ帳の置換ダイアログを表示

[createLink url="/script/function/exec/"]でメモ帳を起動し、メモ帳に対してCtrl＋Hを実行し置換ダイアログを表示します。

UWSC

DIM ID = EXEC("notepad")
SCKEY(ID, VK_CTRL, VK_H)

CopyDIM ID = EXEC("notepad") SCKEY(ID, VK_CTRL, VK_H)

使用関数

SCKEY関数(1)

関連記事

ACW関数 (スクリプト関数)

指定したIDのウィンドウの位置・サイズを変更します。IDのみを指定した場合、そのウィンドウをアクティブにします。

CHKBTN関数 (スクリプト関数)

指定したIDのウィンドウにあるチェックボックス・ラジオボタンがチェックされているかを返します。

CLKITEM関数 (スクリプト関数)

指定したIDのウィンドウのアイテムをクリックします。アイテムに指定できるものにはボタン・チェックボックス・ラジオボタン・リストボックス・コンボボックス・タブコントロール・メニュー・ツリービュー・リストビュー・ツールバー・リンクがあります。

GETID関数 (スクリプト関数)

指定したウィンドウのIDを取得します。第一引数に取得したいウィンドウのタイトル（一部でも可）を指定します。UWSCでウィンドウを操作するのによく使う関数です。

GETITEM関数 (スクリプト関数)

指定したIDのウィンドウのキャプション文字やリストなどを取得します。取得した情報は配列変数のALL_ITEM_LIST[ ]に格納されます。戻値は取得した数でInteger型です。

HNDTOID関数 (スクリプト関数)

引数に指定したハンドル値をIDに変換して返します。IDをハンドル値に変換するにはIDTOHND関数を使います。

CTRLWIN関数 (スクリプト関数)

ウィンドウの状態を操作します。ウィンドウを終了、アクティブ化、表示・非表示、最大化・最小化などができます。

GETALLWIN関数 (スクリプト関数)

全ウィンドウのIDを取得します。

IDTOHND関数 (スクリプト関数)

引数に指定したIDをハンドル値に変換して返します。ハンドル値をIDに変換するにはHNDTOID関数を使います。

MOUSEORG関数 (スクリプト関数)

マウス座標を相対座標にする、 またはマウスとキー情報を直接ウィンドウへ送ります。