TRIM関数

本ページには広告が含まれています。

文字列の両端の空白と制御文字を取り除きます。

構文

UString = TRIM( 文字列, 全角空白 )

引数

文字列（String）必須

文字列

全角空白（Boolean = False）省略可

FALSE: 全角の空白は含めない（デフォルト）
TRUE: 全角の空白を含めて削除

戻り値: 両端の空白と制御文字が取り除かれた文字列

制御文字

コンピューターで文字データを扱うとき改行などを制御する特別な文字で、画面や印刷には表示されません。

以下の表は制御文字の一覧で、TRIM関数では0x7FのDEL以外の制御文字を取り除くことができます。

コード		キャレット記法	略号	名称
10進数	16進数	キャレット記法	略号	名称
0	0x00	^@	NUL	空文字 Null
1	0x01	^A	SOH	ヘッダー開始 Start of Heading
2	0x02	^B	STX	テキスト開始 Start of Text
3	0x03	^C	ETX	テキスト終了 End of Text
4	0x04	^D	EOT	転送終了 End of Transmission
5	0x05	^E	ENQ	照会 Enquiry
6	0x06	^F	ACK	受信OK Acknowledge
7	0x07	^G	BEL	警告(ベル) Bell
8	0x08	^H	BS	後退 Backspace
9	0x09	^I	HT	タブ Horizontal Tabulation
10	0x0A	^J	LF	改行 Line Feed
11	0x0B	^K	VT	垂直タブ Vertical Tabulation
12	0x0C	^L	FF	改ページ Form Feed
13	0x0D	^M	CR	復帰 Carriage Return
14	0x0E	^N	SO	シフトアウト Shift Out
15	0x0F	^O	SI	シフトイン Shift In
16	0x10	^P	DLE	データリンクエスケープ Data Link Escape
17	0x11	^Q	DC1	装置制御1 Device Control 1
18	0x12	^R	DC2	装置制御2 Device Control 2
19	0x13	^S	DC3	装置制御3 Device Control 3
20	0x14	^T	DC4	装置制御4 Device Control 4
21	0x15	^U	NAK	受信失敗 Negative Acknowledge
22	0x16	^V	SYN	同期 Synchronous Idle
23	0x17	^W	ETB	転送ブロック終了 End of Transmission Block
24	0x18	^X	CAN	キャンセル Cancel
25	0x19	^Y	EM	メディア終了 End of Medium
26	0x1A	^Z	SUB	置換 Substitute Character
27	0x1B	^[	ESC	エスケープ Escape
28	0x1C	^\	FS	フォーム区切 File Separator
29	0x1D	^]	GS	グループ区切 Group Separator
30	0x1E	^^	RS	レコード区切 Record Separator
31	0x1F	^_	US	ユニット区切 Unit Separator
127	0x7F	^?	DEL	削除 Delete

タブ（0x09）と改行（0x0D0x0A）はUWSCで特殊文字として用意されているので、それぞれ<#TAB>、<#CR>で書き換えることができます。

制御文字は直接文字として入力することはできませんが、CHR関数に10進数の値を指定することで制御文字に一致させることができます。

使い方

両端の制御文字を取り除く

stringの両端のタブ（制御文字）を取り除きます。

結果

制御文字が連続している場合は、連続するすべての制御文字が取り除かれます。

結果

種類の違う制御文字が連続している場合でも、すべて取り除かれます。

結果

取り除かれるのは先頭もしくは末尾から連続する制御文字のため、文中の制御文字を取り除くことはできません。以下の場合両端の<#TAB>は削除されますが、文中の<#CR>は削除されません。

結果

一部の制御文字のみ取り除く

CHR関数とPOS関数を組み合わせて制御文字の位置を取得することで、一部の制御文字のみを取り除くことができます。

以下は0x09であるタブの位置を取得するプログラムです。stringの中でタブが最初に見つかった位置が1文字目なので1が返ります。

結果

stringから連続する左側のタブのみ取り除くには以下のように記述します。1文字目がタブならstringに2文字目以降を代入を繰り返すことで左側のタブを取り除いています。

結果

右側のタブを取り除くにはPOS関数の第三引数に-1を指定し、後ろからサーチします。左側のタブはそのまま残ります。[HT]がタブを表しています。

結果

文中の制御文字を取り除く

両端だけでなく文字列全体から特定の制御文字を取り除きたい場合は、CHR関数とREPLACE関数の組み合わせで置換することができます。以下はstringからCR、LFの続く制御文字を取り除きます。CRLFはWindowsでよく使われる改行を意味する制御文字です。

結果

CRだけ取り除く場合は、以下のように記述します。

結果

LFだけ取り除く場合は、以下のように記述します。

結果

全角スペース

第二引数にTrueを指定すると両端の全角スペースを取り除くことができます。

結果

制御文字

以下のプログラムはTRIM関数で制御文字を取り除くプログラムです。UWSC Debuggerでは制御文字の入力ができないため、サクラエディタで編集して実行しています。

実行時は制御文字を直接入力してテストしていますが、制御文字は通常見えなく区別もつかないため可視化しています。[　]で囲まれたアルファベットが制御文字を表しています。以下のプログラムは制御文字を直接入力しているわけではないため、実行しても制御文字は取り除くことはできません。

TRIM関数を実行する前の文字数と実行した後の文字数を比較し、変化があれば制御文字を取り除けたと判定しTrueを、取り除けなければFalseと出力しています。

以下の結果からわかるように0x00〜0x1Fの範囲の制御文字はTRIM関数で取り除くことができますが、0x7Fの削除(DEL)のみは取り除くことができません。

結果

トリム前,                           トリム後,                 トリム有無
[SOH]ヘッダー開始[SOH],             ヘッダー開始,             True
[STX]テキスト開始[STX],             テキスト開始,             True
[ETX]テキスト終了[ETX],             テキスト終了,             True
[EOT]転送終了[EOT],                 転送終了,                 True
[ENQ]照会[ENQ],                     照会,                     True
[ACK]受信OK[ACK],                   受信OK,                   True
[BEL]警告(ベル)[BEL],               警告(ベル),               True
[BS]後退[BS],                       後退,                     True
[HT]タブ[HT],                       タブ,                     True
[LF]改行[LF],                       改行,                     True
[VT]垂直タブ[VT],                   垂直タブ,                 True
[FF]改ページ[FF],                   改ページ,                 True
[CR]復帰[CR],                       復帰,                     True
[SO]シフトアウト[SO],               シフトアウト,             True
[SI]シフトイン[SI],                 シフトイン,               True
[DLE]データリンクエスケープ[DLE],   データリンクエスケープ,   True
[DC1]装置制御1[DC1],                装置制御1,                True
[DC2]装置制御2[DC2],                装置制御2,                True
[DC3]装置制御3[DC3],                装置制御3,                True
[DC4]装置制御4[DC4],                装置制御4,                True
[NAK]受信失敗[NAK],                 受信失敗,                 True
[SYN]同期[SYN],                     同期,                     True
[ETB]転送ブロック終了[ETB],         転送ブロック終了,         True
[CAN]キャンセル[CAN],               キャンセル,               True
[EM]メディア終了[EM],               メディア終了,             True
[SUB]置換[SUB],                     置換,                     True
[ESC]エスケープ[ESC],               エスケープ,               True
[FS]フォーム区切[FS],               フォーム区切,             True
[GS]グループ区切[GS],               グループ区切,             True
[RS]レコード区切[RS],               レコード区切,             True
[US]ユニット区切[US],               ユニット区切,             True
[DEL]削除[DEL],                     [DEL]削除[DEL],           False

プログラム実行例

システムの起動時間を取得

システムの起動時間をyyyy年m月d日 h:n:sの形式で取得します。

PRINT TRIM(POWERSHELL("[Management.ManagementDateTimeConverter]::ToDateTime((Get-WmiObject Win32_OperatingSystem).LastBootUpTime)"))

//////////////////////////////////////////////////
// 【引数】
//   cmd : 実行するPowerShellのコマンド
//   debug : デバッグを表示を場合はTrue、表示しない場合はFalse
// 【戻り値】
//////////////////////////////////////////////////
MODULE PowerShell
	DIM title = "PowerShellフォーム"
	DIM class = "WindowsForms10.Window.8.app"
	PROCEDURE Create(debug = FALSE)
		DIM ID = GETID(title, class)
		IFB ID = -1 THEN
			DIM ProcessId = STATUS(GETID(GET_THISUWSC_WIN), ST_PROCESS)
			script = REPLACE(source, "%TITLE%", title)
			script = REPLACE(script, "%PROCESSID%", processId)
			IFB debug THEN
				script = REPLACE(script, "%DEBUG%", "$true")
			ELSE
				script = REPLACE(script, "%DEBUG%", "$false")			
			ENDIF
			POWERSHELL(script, TRUE, FALSE)
			ID = GETID(title,, 5)
		ENDIF
		ProcessId = STATUS(ID, ST_TITLE)
		IFB STATUS(ID, ST_ISID) THEN
			CTRLWIN(ID, SHOW)
		ELSE
			MSGBOX("PowerShellの実行に失敗しました。")
			EXIT
		ENDIF
	FEND
	FUNCTION Execute(cmd)
		Create()
		DIM ID = GETID(title, class)
		CTRLWIN(ID, SHOW)
		CLKITEM(ID, "リセット")
		SENDSTR(ID, cmd, 1, TRUE)
		CLKITEM(ID, "実行")
		DIM t = GETTIME()
		REPEAT
			RESULT = GETSTR(ID, 0, STR_ACC_STATIC)
		UNTIL RESULT <> "" OR GETTIME() - t >= 3
	FEND
	FUNCTION Quit()
		RESULT = CLKITEM(GETID(title, class), "終了")
	FEND
TEXTBLOCK source
add-type -assembly system.windows.forms
$title = "%TITLE%"
$processId = "%PROCESSID%"
$doNotShow = !%DEBUG%
$prompt = ""
$timer = new-object windows.forms.timer -property @{interval=60}
$form = new-object windows.forms.form -property @{text=$title}
$form.Width = 300
$form.Height = 300
$timer.add_tick({
	if(ps -id $processId){
	}else{
		ps -id $pid|kill
	}
})
$form.add_shown({$timer.start()})
$base = new-object windows.forms.flowlayoutpanel -property @{dock="fill";parent=$form}
$inBox = new-object windows.forms.textbox -property @{
	parent = $base;
	multiline = $true;
	text = $prompt;
	width = 280
}
 
$reset = new-object windows.forms.button -property @{
	parent = $base;
	text = "リセット"
}
$exec = new-object windows.forms.button -property @{
	parent = $base;
	text = "実行"
}
$quit=new-object windows.forms.button -property @{
	parent = $base;
	text = "終了";
	dialogresult = "OK"
}
$outLabel = new-object windows.forms.label -property @{
	parent = $base;
	text = $prompt;
	width = 280;
	height = 150
}
$reset.add_click({
	$outLabel.text=$prompt
	$inBox.text=$prompt
})
$exec.add_click({
	try{
		$res=Invoke-Expression $inBox.text
		$type=Invoke-Expression ("(" + $inBox.text + ").GetType()")
		$res = $type
		if(($type -eq [System.Object[]])-Or ($type -eq [hashtable])){
			$properties = Invoke-Expression ("(" + $inBox.text + " | Get-Member -MemberType Property | Select-Object -ExpandProperty Name) -join ','")
			$res = Invoke-Expression ("((" + $inBox.text + ") | Select-Object " + $properties + " | ConvertTo-Csv -NoTypeInformation) -join '`r`n'")
		}else{
			$res = Invoke-Expression $inBox.text
		}
	}catch{
		$res=$error[0]
	}
	$outLabel.text=$res
	$inBox.text=$prompt
})
if($doNotShow){
	$form.opacity=0.01
	$form.formborderstyle="none"
}
$form.showdialog()
ENDTEXTBLOCK
ENDMODULE

結果

使用関数

「Yahoo!テレビ.Gガイド [テレビ番組表]」から番組表データを取得する

CONST xlCenter = -4108
CONST xlTop = -4160
CONST xlContinuous = 1
CONST xlUp = -4162
CONST xlLastCell = 11
CONST xlGeneral = 1

HASHTBL rows
HASHTBL previousDay

GETTIME()
DIM date = G_TIME_YY4 + G_TIME_MM2 + G_TIME_DD2
DIM days[] = "日", "月", "火", "水", "木", "金", "土"
DIM dt = G_TIME_MM + "/" + G_TIME_DD + "<#CR>(" + days + ")"
DIM va = 24

DIM IE = IEBoot()
IE.Navigate("https://tv.yahoo.co.jp/listings/10/?&d=" + date + "&s=1&va=" + va + "&vb=1&vc=0&vd=0&ve=1&st=4")

BusyWait(IE)

DIM element, elements

element = IE.document.getElementById("Tables")
//elememts = element.getElementsByTagName("table")
elements = element.getElementsByClassName("turnup")
//elements = element.querySelector(".turnup")

SLEEP(3.00)

DIM Excel = ExcelBoot()
//Excel.Cells(1, 1).Interior.Color = 249 + 210 * 256 + 228 * 65536

Excel.Rows.RowHeight = 1
Excel.Columns.ColumnWidth = 35	// 22

WITH Excel.Cells
	WITH .Font
		.Size = 10
		.Name = "メイリオ"
	ENDWITH
	.VerticalAlignment = xlTop
	.WrapText = TRUE
ENDWITH

// フォント メイリオ
// サイズ 10
// 折り返して全体を表示

Excel.ScreenUpdating = FALSE

DIM num = elements.length
FOR i = 0 TO num - 1
	FUKIDASI(i + "/" + (num-1))
	WITH elements.Item(i)
TRY
		DIM len = VAL(.getAttribute("rowspan"))
		DIM time = .getElementsByClassName("time").Item(0).innerText
		DIM times = SPLIT(time, ":")
		DIM hour = VAL(times[0])
		DIM minute = VAL(times[1])
		DIM ttl = .getElementsByClassName("title").Item(0).innerText
		DIM str = .getElementsByTagName("a").Item(0).dataset.ylk
		DIM ch = VAL(COPY(str, POS("pos:", str) + 4))
		DIM note = TRIM(getDirectChildText(.getElementsByClassName("detail").Item(0)))
		IF hour < 24 THEN previousDay[ch] = TRUE
		IF previousDay[ch] <> TRUE THEN hour = hour MOD 24
		DIM row = hour * 60 + minute - 4 * 60 + 1
		IFB row >= 0 THEN
			TRY
			WITH Excel
				WITH .Cells(row, ch)
					DIM text = time + "　" + ttl + "<#CR>" + note
					.Value = text
					.Characters(LENGTH(time) + 2, LENGTH(ttl)).Font.FontStyle = "ボールド"
try
					IFB LENGTH(note) > 0 THEN
						.Characters(LENGTH(time + " " + ttl) + 2).Font.FontSize = 8
					ELSE
					ENDIF
except
endtry
				ENDWITH
			ENDWITH
			EXCEPT
			ENDTRY
		ENDIF
		SELECT TRUE
			CASE POS("cellBGAnime", .outerHTML) <> 0
				Excel.Cells(row, ch).Interior.Color = 249 + 210 * 256 + 228 * 65536
			CASE POS("cellBGMusic", .outerHTML) <> 0
				Excel.Cells(row, ch).Interior.Color = 253 + 228 * 256 + 206 * 65536
			CASE POS("cellBGSports", .outerHTML) <> 0
				Excel.Cells(row, ch).Interior.Color = 226 + 238 * 256 + 198 * 65536
			CASE POS("cellBGDrama", .outerHTML) <> 0
				Excel.Cells(row, ch).Interior.Color = 255 + 250 * 256 + 178 * 65536
			CASE POS("cellBGMovie", .outerHTML) <> 0
				Excel.Cells(row, ch).Interior.Color = 212 + 229 * 256 + 198 * 65536
			CASE POS("GrayBg", .outerHTML) <> 0
				Excel.Cells(row, ch).Interior.Color = 220 + 220 * 256 + 220 * 65536
		SELEND
EXCEPT
print try_errline
ENDTRY
	ENDWITH
NEXT

Excel.ScreenUpdating = TRUE

WITH Excel
	FOR col = 1 TO 7
		.ScreenUpdating = FALSE
		DIM LastRow = va * 60
		REPEAT
			DIM Range = .Cells(LastRow, col).End(xlUp)
			IFB .Cells(LastRow, col).Value <> "" THEN
				LastRow = LastRow - 1
				CONTINUE
			ENDIF
			IF LastRow - Range.Row > 1 THEN .Range(.Cells(Range.Row, col), .Cells(LastRow, col)).Merge
			LastRow = Range.Row - 1
		UNTIL Range.Row = 1
		.ScreenUpdating = TRUE
	NEXT
ENDWITH

// ch
elements = IE.document.getElementById("ListingsHeader")
elements = elements.getElementsByClassName("station")

WITH Excel
	.Rows(1).Insert
	.Rows(1).RowHeight = 30
ENDWITH

num = elements.length

FOR i = 0 TO num - 1
	Excel.Cells(1, i + 1) = elements.Item(i).innerText
NEXT

WITH Excel.Range(Excel.Cells(1, 1), Excel.Cells(1, num))
	.HorizontalAlignment = xlCenter
	.VerticalAlignment = xlCenter
ENDWITH

IE.Quit

//Excel.ScreenUpdating = FALSE

// じかんたい きにゅう
DIM h[] = 8, 3

FOR col IN h
	WITH Excel
		.Columns(col).Insert
		.Columns(col).ColumnWidth = 3.5
		FOR i = 0 TO 23
			hour = i + 4
 			WITH .Cells(i * 60 + 2, col)
				.Value = hour
				SELECT TRUE
					CASE hour >= 4 AND hour < 12
						.Interior.Color = 250 + 198 * 256 + 0 * 65536
					CASE hour >= 12 AND hour < 18
						.Interior.Color = 188 + 209 * 256 + 0 * 65536
					CASE hour >= 18 AND hour < 23
						.Interior.Color = 56 + 171 * 256 + 224 * 65536
					CASE hour >= 23
						.Interior.Color = 2 + 80 * 256 + 138 * 65536
				SELEND
			ENDWITH
			.Range(Excel.Cells(i * 60 + 2, col), Excel.Cells((i + 1) * 60 + 1, col)).Merge
		NEXT
	ENDWITH
	WITH Excel.Columns(col)
		.HorizontalAlignment = xlCenter
		.Font.Bold = TRUE
		.Font.Color = 255 + 255 * 256 + 255 * 65536
		.Font.Size = 12
		.VerticalAlignment = xlCenter
	ENDWITH
NEXT

// けいせんをひく
DIM LastCell = Excel.Range("A1").SpecialCells(xlLastCell)

WITH Excel.Range("A1", Excel.Cells(LastCell.Row, LastCell.Column)).Borders
	.LineStyle = xlContinuous
	.ThemeColor = 1
	.TintAndShade = -0.349986266670736
ENDWITH

WITH Excel.Range("J1:J200")
	.Merge
	.Value = dt
	WITH .Font
		.Size = 60
		.Color = 255 + 255 * 256 + 255 * 65536
	ENDWITH
	.HorizontalAlignment = xlCenter
	.VerticalAlignment = xlCenter
	.Interior.Color = 5296274		// へいじつ、どにち、しゅくじつ
ENDWITH

//Excel.ScreenUpdating = TRUE

// 要素直下のテキストを取得
FUNCTION getDirectChildText(element)
	DIM res = ""
	FOR elem IN element.childNodes
		IF elem.nodeName = "#text" THEN res = res + elem.nodeValue
	NEXT
	RESULT = res
FEND

//////////////////////////////////////////////////
// 【引数】
//   array : 要素を追加する配列（参照引数）
//   values : 追加する要素をvalue1から指定
// 【戻り値】
//   処理後の配列の要素の数
//////////////////////////////////////////////////
FUNCTION arrayPush(var array[], value1 = EMPTY, value2 = EMPTY, value3 = EMPTY, value4 = EMPTY, value5 = EMPTY, value6 = EMPTY, value7 = EMPTY, value8 = EMPTY, value9 = EMPTY, value10 = EMPTY, value11 = EMPTY, value12 = EMPTY, value13 = EMPTY, value14 = EMPTY, value15 = EMPTY, value16 = EMPTY)
    DIM i = 1
    WHILE EVAL("value" + i) <> EMPTY
	  DIM res = RESIZE(array, UBound(array) + 1)
	  array[res] = EVAL("value" + i)
	  i = i + 1
	WEND
	RESULT = LENGTH(array)
FEND

//////////////////////////////////////////////////
// 【引数】
//   needle : 検索する値
//   haystack : 配列
// 【戻り値】
//   needleが見つかった場合に配列のキー
//////////////////////////////////////////////////
FUNCTION arraySearch(needle, haystack[])
	DIM i = 0
	FOR item IN haystack
		IFB item = needle THEN
			RESULT = i
			EXIT
		ENDIF
		i = i + 1
	NEXT
FEND

//////////////////////////////////////////////////
// 【引数】
//   IE : IEオブジェクト
// 【戻り値】
//////////////////////////////////////////////////
PROCEDURE BusyWait(Var IE)
	SLEEP(0.500)
	DIM t = GETTIME()
	TRY
		REPEAT
			DIM tm = GETTIME() - t
			FUKIDASI("BusyWait：" + tm)
			SLEEP(0.010)
			IF tm >= 60 THEN BREAK
		UNTIL !IE.Busy AND IE.readyState = 4
	EXCEPT
		IE = getIEObj(-1)
		PRINT IE.document.URL + " のIEオブジェクトを取得しました。"
		BusyWait(IE)
	ENDTRY
	FUKIDASI()
FEND

//////////////////////////////////////////////////
// 【引数】
//   interval : 加算する時間間隔を表す文字列式（yyyy：年、m：月、d：日、ww：週、h：時、n：分、s：秒）
//   num : dateに加算する値。未来は正、過去は負で指定
//   date : 時間間隔を加算する日付
// 【戻り値】
//   日時（date）に、指定した単位（interval）の時間（num）を加算して返します
//////////////////////////////////////////////////
FUNCTION dateAdd(interval, num, date)
	DIM year, month, day, d
	GETTIME(0, date)
	DIM time = G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2
	SELECT interval
		CASE "yyyy"
			d = (G_TIME_YY + num) + "/" + G_TIME_MM2 + "/" + G_TIME_DD2
			IF time <> "00:00:00" THEN d = d + " " + time
		CASE "m"
			IFB num > 0 THEN
				year = G_TIME_YY + INT((G_TIME_MM + num) / 12)
				month = REPLACE(FORMAT(((G_TIME_MM + num) MOD 12), 2), " ", "0")
			ELSE
				year = G_TIME_YY + CEIL((G_TIME_MM + num) / 12 - 1)
				month = REPLACE(FORMAT(G_TIME_MM - (ABS(num) MOD 12), 2), " ", "0")
			ENDIF
			IF month = "00" THEN month = 12
			day = G_TIME_DD2
			d = "" + year + month + day
			IFB !isDate(d) THEN
				d = year + "/" + month + "/" + "01"
				d = getEndOfMonth(d)
			ELSE
				d = year + "/" + month + "/" + day
			ENDIF
			IF time <> "00:00:00" THEN d = d + " " + time
		CASE "d"
			t = GETTIME(num, date)
			d = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + IIF(t MOD 86400, " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2, "")
		CASE "ww"
			t = GETTIME(num * 7, date)
			d = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + IIF(t MOD 86400, " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2, "")
		CASE "h"
			t = GETTIME(num / 24, date)
			d = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + IIF(t MOD 86400, " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2, "")
		CASE "n"
			t = GETTIME(num / 1440, date)
			d = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + IIF(t MOD 86400, " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2, "")
		CASE "s"
			t = GETTIME(num / 86400, date)
			d = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + IIF(t MOD 86400, " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2, "")
	SELEND
	RESULT = d
FEND

//////////////////////////////////////////////////
// 【引数】
//   interval : 時間単位（yyyy︰年、q：四半期、m︰月、d︰日、w：週日、ww：週、h：時、n：分、s：秒）
//   date1 : 日時1
//   date2 : 日時2
// 【戻り値】
//   date2からdate1を引いた時間間隔を求めます。
//////////////////////////////////////////////////
FUNCTION dateDiff(interval, date1, date2)
	DIM y1, y2, m1, m2, d1, d2, d
	SELECT interval
		CASE "yyyy"
			GETTIME(0, date1)
			y1 = G_TIME_YY
			GETTIME(0, date2)
			y2 = G_TIME_YY
			d = y2 - y1
		CASE "q"
			GETTIME(0, date1)
			y1 = G_TIME_YY
			m1 = G_TIME_MM
			GETTIME(0, date2)
			y2 = G_TIME_YY
			m2 = G_TIME_MM
			d = y2 * 4 + CEIL(m2/3) - (y1 * 4 + CEIL(m1/3))
		CASE "m"
			GETTIME(0, date1)
			y1 = G_TIME_YY
			m1 = G_TIME_MM
			GETTIME(0, date2)
			y2 = G_TIME_YY
			m2 = G_TIME_MM
			d = (y2 - y1) * 12 + m2 - m1
		CASE "d"
			d1 = GETTIME(0, date1)
			d2 = GETTIME(0, date2)
			d = (d2 - d1) / 86400
		CASE "w"
			d = INT(dateDiff("d", date1, date2) / 7)
		CASE "ww"
			date1 = dateAdd("d", -1 * getWeekday(date1), date1)
			d = INT(dateDiff("d", date1, date2) / 7)
		CASE "h"
			d = dateDiff("d", date1, date2) * 24
		CASE "n"
			d = dateDiff("d", date1, date2) * 1440
		CASE "s"
			d = dateDiff("d", date1, date2) * 86400
	SELEND
	RESULT = d
FEND

//////////////////////////////////////////////////
// 【引数】
//   path : 開くファイルのパス名
// 【戻り値】
//   <a href="https://uwsc.jp/com/excel/">Excel オブジェクト</a>
//////////////////////////////////////////////////
FUNCTION ExcelBoot(path = "")
	DIM Excel = CREATEOLEOBJ("Excel.Application")
	Excel.Visible = TRUE
	IFB path = "" THEN
		Excel.Workbooks.Add
	ELSE
		DIM FSO = CREATEOLEOBJ("Scripting.FileSystemObject")
		IFB FSO.GetParentFolderName(path) = "" THEN
			path = GET_CUR_DIR + "\" + path
		ENDIF
		Excel.Workbooks.Open(path)
	ENDIF
	RESULT = Excel
FEND

//////////////////////////////////////////////////
// 【引数】
//   array : 最大公約数を求める数値を格納した配列
// 【戻り値】
//   最大公約数
//////////////////////////////////////////////////
FUNCTION GCD(array[])
	DIM c = LENGTH(array)
	DIM rem = array[c-1] MOD array[c-2]
	IFB rem = 0 THEN
		IFB LENGTH(array) = 2 THEN
			RESULT = array[c-2]
			EXIT
		ENDIF
		RESIZE(array, c-2)
		RESULT = GCD(array)
		EXIT
	ENDIF
	array[c-1] = array[c-2]
	array[c-2] = rem
	RESULT = GCD(array)
FEND

//////////////////////////////////////////////////
// 【引数】
//   date : 日付（”YYYYMMDD” or “YYYY/MM/DD” or “YYYY-MM-DD” or “YYYYMMDDHHNNSS” or “YYYY/MM/DD HH:NN:SS”）
//   m : 第一引数の指定日からプラスマイナスm月とする
// 【戻り値】
//   dateからm月後の月末の日付
//////////////////////////////////////////////////
FUNCTION getEndOfMonth(date, m = 0)
	date = dateAdd("m", m + 1, date)
	GETTIME(0, date)
	GETTIME(-G_TIME_DD, date)
	RESULT = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2
FEND

//////////////////////////////////////////////////
// 【引数】
//   文字列 or 数値 : 取得したい<a href="https://uwsc.jp/com/ie/">InternetExplorer オブジェクト</a>のタイトル・URLもしくは数値を指定
//   完全一致フラグ : （TRUE : 文字列が完全一致したものを取得、FALSE : 文字列の一部を含むものを取得）
// 【戻り値】
//   条件に一致する<a href="https://uwsc.jp/com/ie">InternetExplorer</a>
//////////////////////////////////////////////////
FUNCTION getIEObj(str, flg = FALSE)
	DIM Shell = CREATEOLEOBJ("Shell.Application")
	DIM ShellWindows = Shell.Windows
	DIM IE[-1]
	FOR i = 0 TO ShellWindows.Count - 1
		TRY
			IFB ShellWindows.Item(i).Name = "Internet Explorer" THEN
				arrayPush(IE, ShellWindows.Item(i))
			ENDIF
		EXCEPT
		ENDTRY
	NEXT
	SELECT CHKNUM(str)
		CASE TRUE
			IFB str = 0 THEN
				RESULT = LENGTH(IE)
			ELSE
				IF str < 0 THEN str = str + LENGTH(IE) + 1
				TRY
					RESULT = IE[str-1]
				EXCEPT
					RESULT = ERR_VALUE
				ENDTRY
			ENDIF
		CASE FALSE
			DIM pattern = IIF(flg, "^" + str + "$", str)
			DIM titleList = SLICE(IE)
			FOR i = 0 TO UBound(titleList)
				titleList[i] = titleList[i].Document.title
			NEXT
			DIM urlList = SLICE(IE)
			FOR i = 0 TO UBound(urlList)
				urlList[i] = urlList[i].Document.URL
			NEXT
			DIM num = ERR_VALUE
			SELECT TRUE
				CASE pregGrep(pattern, titleList) <> FALSE;	num = arraySearch(pregGrep(pattern, titleList)[0], titleList)
				CASE pregGrep(pattern, urlList) <> FALSE;		num = arraySearch(pregGrep(pattern, urlList)[0], urlList)
			SELEND
			TRY
				RESULT = IE[num]
			EXCEPT
				RESULT = ERR_VALUE
			ENDTRY
	SELEND
FEND

//////////////////////////////////////////////////
// 【引数】
//   date : 日付文字列（”YYYYMMDD” or “YYYY/MM/DD” or “YYYY-MM-DD” or “YYYYMMDDHHNNSS” or “YYYY/MM/DD HH:NN:SS”）もしくはシリアル値
//   type : 取得する曜日番号の種類を示す0〜3または11〜17の値。1と17は日曜日を1、2と11は月曜日を1とカウントします。11以降はExcel2010で追加された値で、互換性を保つために重複した値があります。
// 【戻り値】
//   typeで指定した種類によって以下の値を返します。 : （0 : 0(日曜)〜6(土曜)、1 : 1(日曜)～7(土曜)、2 : 1(月曜)～7(日曜)、3 : 0(月曜)〜6(日曜)、11 : 1(月曜)～7(日曜)、12 : 1(火曜)～7(月曜)、13 : 1(水曜)～7(火曜)、14 : 1(木曜)～7(水曜)、15 : 1(金曜)～7(木曜)、16 : 1(土曜)～7(金曜)、17 : 1(日曜)～7(土曜)）
//////////////////////////////////////////////////
FUNCTION getWeekday(date, type = 1)
	IF VARTYPE(date) <> 258 THEN date = text(date, "yyyy/mm/dd")
	GETTIME(0, date)
	DIM w = G_TIME_WW
	SELECT TRUE
		CASE type = 0
			RESULT = w
		CASE type = 1
			RESULT = w + 1
		CASE type = 2
			RESULT = IIF(w=0, 7, w)
		CASE type = 3
			RESULT = (w+6) MOD 7
		CASE type >= 11
			RESULT = ((getWeekday(date, 2) + 17 - type) MOD 7) + 1
	SELEND
FEND

//////////////////////////////////////////////////
// 【引数】
//   serial : シリアル値もしくは時刻文字列
// 【戻り値】
//   時刻から時間を表す0〜23の範囲の値
//////////////////////////////////////////////////
FUNCTION Hour(serial)
	IF VARTYPE(serial) = 258 THEN serial = timeValue(serial)
	RESULT = INT(serial * 24) MOD 24
FEND

//////////////////////////////////////////////////
// 【引数】
//   InPrivate : InPrivateブラウズ・モードを有効にするときはTRUEを指定
// 【戻り値】
//   InternetExplorerオブジェクト
//////////////////////////////////////////////////
FUNCTION IEBoot(InPrivate = FALSE)
	DIM IE
	SELECT InPrivate
		CASE TRUE
			DOSCMD("start iexplore -private")
			GETID("InPrivate - Internet Explorer - [InPrivate]", "IEFrame", -1)
			IE = GETACTIVEOLEOBJ("InternetExplorer.Application","InPrivate - Internet Explorer - [InPrivate]")
		CASE FALSE
			TRY
				IE = CREATEOLEOBJ("InternetExplorer.Application")
				IE.Visible = TRUE
			EXCEPT
				EXEC("C:\Program Files\Internet Explorer\iexplore.exe")
				GETID("Internet Explorer", "IEFrame", -1)
				TRY
					IE = GETACTIVEOLEOBJ("InternetExplorer.Application")	
				EXCEPT
					IE = getIEObj(-1)
				ENDTRY
			ENDTRY
	SELEND
	RESULT = IE
FEND

//////////////////////////////////////////////////
// 【引数】
//   expr : 評価する式
//   truepart : 評価した式がTrueのときに返す値
//   falsepart : 評価した式がFalseのときに返す値
// 【戻り値】
//   truepart : 評価した式がTrueのとき、falsepart : 評価した式がFalseのとき
//////////////////////////////////////////////////
FUNCTION IIF(expr, truepart, falsepart)
	IFB EVAL(expr) THEN
		RESULT = truepart
	ELSE
		RESULT = falsepart
	ENDIF
FEND

//////////////////////////////////////////////////
// 【引数】
//   date : 存在するかを調べる日付文字列。YYYYMMDD or YYYY/MM/DD or YYYY-MM-DDのいずれかの形式。
// 【戻り値】
//   TRUE : 日付として認識できる、FALSE : 日付として認識できない
//////////////////////////////////////////////////
FUNCTION isDate(date)
	TRY
		GETTIME(0, date)
		RESULT = TRUE
	EXCEPT
		RESULT = FALSE
	ENDTRY
FEND

//////////////////////////////////////////////////
// 【引数】
//   pattern : 検索するパターンを表す文字列
//   array : 検索される配列
// 【戻り値】
//////////////////////////////////////////////////
FUNCTION pregGrep(pattern, array[], flags = 0)
	DIM res[-1]
	FOR item IN array
		IF reTest(item, pattern) THEN arrayPush(res, item)
	NEXT
	RESULT = SLICE(res)
FEND

//////////////////////////////////////////////////
// 【引数】
//   str : 正規表現による検索の対象となる文字列
//   Pattern : 正規表現で使用するパターンを設定
//   IgnoreCase : 大文字・小文字を区別しない場合はTrue、区別する場合はFalse
//   Global : 文字列全体を検索する場合はTrue、しない場合はFalse
// 【戻り値】
//   正規表現で検索した結果をMatchesコレクションとして返します。
//////////////////////////////////////////////////
FUNCTION reExecute(str, Pattern, IgnoreCase = TRUE, Global = TRUE)
	DIM re = CREATEOLEOBJ("VBScript.RegExp")
	re.Pattern = Pattern
	re.IgnoreCase = IgnoreCase
	re.Global = Global
	RESULT = re.Execute(str)
FEND

//////////////////////////////////////////////////
// 【引数】
//   str : 正規表現による検索の対象となる文字列
//   Pattern : 正規表現で使用するパターンを設定
//   IgnoreCase : 大文字・小文字を区別しない場合はTrue、区別する場合はFalse
//   Global : 文字列全体を検索する場合はTrue、しない場合はFalse
// 【戻り値】
//   正規表現にマッチするかどうかを示すブール値
//////////////////////////////////////////////////
FUNCTION reTest(str, Pattern, IgnoreCase = TRUE, Global = TRUE)
	DIM re = CREATEOLEOBJ("VBScript.RegExp")
	re.Pattern = Pattern
	re.IgnoreCase = IgnoreCase
	re.Global = Global
	RESULT = re.Test(str)
FEND

//////////////////////////////////////////////////
// 【引数】
//   inputs : 繰り返す文字列
//   multiplier : inputsを繰り返す回数
// 【戻り値】
//   inputsをmultiplier回を繰り返した文字列を返します
//////////////////////////////////////////////////
FUNCTION strRepeat(inputs, multiplier)
	DIM res = ""
	FOR n = 1 TO multiplier
		res = res + inputs
	NEXT
	RESULT = res
FEND

//////////////////////////////////////////////////
// 【引数】
//   serial : シリアル値
//   format : フォーマット
// 【戻り値】
//   数値を表示書式に基づいて変換した文字列
//////////////////////////////////////////////////
FUNCTION text(serial, format, hour12 = FALSE)
	HASHTBL startDate
	startDate["明治"] = "1868/01/25"
	startDate["大正"] = "1912/07/30"
	startDate["昭和"] = "1926/12/25"
	startDate["平成"] = "1989/01/08"
	startDate["令和"] = "2019/05/01"
	
	DIM baseDate = "1899/12/30"
	serial = VAL(serial)
	SELECT TRUE
		CASE reTest(format, "\[h+\]")
			Matches = reExecute(format, "\[(h+)\]")
			DIM hour = iif(hour12, Hour(serial) MOD 12, Hour(serial))
			RESULT = text(hour, strRepeat("0", LENGTH(Matches.Item(0).SubMatches(0))))
		CASE reTest(format, "^h+$")
			Matches = reExecute(format, "^(h+)$")
			hour = iif(hour12, Hour(serial) MOD 12, Hour(serial))
			RESULT = text(hour MOD 24, strRepeat("0", LENGTH(Matches.Item(0).SubMatches(0))))
		CASE reTest(format, "\[m+\]")
			Matches = reExecute(format, "\[(m+)\]")
			RESULT = text(serial * 1440, strRepeat("0", LENGTH(Matches.Item(0).SubMatches(0))))
		CASE format = "m"
			GETTIME(serial, baseDate)
			RESULT = text(G_TIME_MM, "0")
		CASE format = "mm"
			GETTIME(serial, baseDate)
			RESULT = G_TIME_MM2
		CASE format = "n"
			GETTIME(serial, baseDate)
			RESULT = G_TIME_NN
		CASE format = "nn"
			GETTIME(serial, baseDate)
			RESULT = G_TIME_NN2
		CASE format = "s"
			GETTIME(serial, baseDate)
			RESULT = text(G_TIME_SS, "0")
		CASE format = "ss"
			GETTIME(serial, baseDate)
			RESULT = G_TIME_SS2
		CASE format = "yyyy"
			GETTIME(serial, baseDate)
			RESULT = G_TIME_YY4
		CASE format = "yy"
			GETTIME(serial, baseDate)
			RESULT = COPY(G_TIME_YY4, 3, 2)
		CASE format = "e"
			SELECT TRUE
				CASE dateDiff("d", startDate["令和"], text(serial, "yyyy/mm/dd")) >= 0
					RESULT = text(serial, "yyyy") - 2018
				CASE dateDiff("d", startDate["平成"], text(serial, "yyyy/mm/dd")) >= 0
					RESULT = text(serial, "yyyy") - 1988
				CASE dateDiff("d", startDate["昭和"], text(serial, "yyyy/mm/dd")) >= 0
					RESULT = text(serial, "yyyy") - 1925
				CASE dateDiff("d", startDate["大正"], text(serial, "yyyy/mm/dd")) >= 0
					RESULT = text(serial, "yyyy") - 1911
				CASE dateDiff("d", startDate["明治"], text(serial, "yyyy/mm/dd")) >= 0
					RESULT = text(serial, "yyyy") - 1867
			SELEND
		CASE format = "ee"
			SELECT TRUE
				CASE dateDiff("d", startDate["令和"], text(serial, "yyyy/mm/dd")) >= 0
					RESULT = text(text(serial, "yyyy") - 2018, "00")
				CASE dateDiff("d", startDate["平成"], text(serial, "yyyy/mm/dd")) >= 0
					RESULT = text(text(serial, "yyyy") - 1988, "00")
				CASE dateDiff("d", startDate["昭和"], text(serial, "yyyy/mm/dd")) >= 0
					RESULT = text(text(serial, "yyyy") - 1925, "00")
				CASE dateDiff("d", startDate["大正"], text(serial, "yyyy/mm/dd")) >= 0
					RESULT = text(text(serial, "yyyy") - 1911, "00")
				CASE dateDiff("d", startDate["明治"], text(serial, "yyyy/mm/dd")) >= 0
					RESULT = text(text(serial, "yyyy") - 1867, "00")
			SELEND
		CASE format = "g"
			SELECT TRUE
				CASE dateDiff("d", startDate["令和"], text(serial, "yyyy/mm/dd")) >= 0;		RESULT = "R"
				CASE dateDiff("d", startDate["平成"], text(serial, "yyyy/mm/dd")) >= 0;		RESULT = "H"
				CASE dateDiff("d", startDate["昭和"], text(serial, "yyyy/mm/dd")) >= 0;		RESULT = "S"
				CASE dateDiff("d", startDate["大正"], text(serial, "yyyy/mm/dd")) >= 0;		RESULT = "T"
				CASE dateDiff("d", startDate["明治"], text(serial, "yyyy/mm/dd")) >= 0;		RESULT = "M"
			SELEND
		CASE format = "gg"
			RESULT = COPY(text(serial, "ggg"), 1, 1)
		CASE format = "ggg"
			SELECT TRUE
				CASE dateDiff("d", startDate["令和"], text(serial, "yyyy/mm/dd")) >= 0;		RESULT = "令和"
				CASE dateDiff("d", startDate["平成"], text(serial, "yyyy/mm/dd")) >= 0;		RESULT = "平成"
				CASE dateDiff("d", startDate["昭和"], text(serial, "yyyy/mm/dd")) >= 0;		RESULT = "昭和"
				CASE dateDiff("d", startDate["大正"], text(serial, "yyyy/mm/dd")) >= 0;		RESULT = "大正"
				CASE dateDiff("d", startDate["明治"], text(serial, "yyyy/mm/dd")) >= 0;		RESULT = "明治"
			SELEND
		CASE format = "mmmmm"
			RESULT = COPY(text(serial, "mmmm"), 1, 1)
		CASE format = "mmmm"
			DIM month[] = "January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November", "December"
			RESULT = month[text(serial, "m") - 1]
		CASE format = "mmm"
			RESULT = COPY(text(serial, "mmmm"), 1, 3)
		CASE format = "dd"
			GETTIME(serial, baseDate)
			RESULT = text(G_TIME_DD2, "00")
		CASE format = "d"
			GETTIME(serial, baseDate)
			RESULT = text(G_TIME_DD, "0")
		CASE reTest(format, "^[ad]{3,4}$")
			Matches = reExecute(format, "([ad]{3,4})")
			GETTIME(serial, baseDate)
			DIM aaa[] = "日", "月", "火", "水", "木", "金", "土"
			DIM aaaa[] = "日曜日", "月曜日", "火曜日", "水曜日", "木曜日", "金曜日", "土曜日"
			DIM ddd[] = "Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat"
			DIM dddd[] = "Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday"
			RESULT = EVAL(Matches.Item(0).SubMatches(0) + "[" + getWeekday(G_TIME_WW, 1) + "]")
		CASE reTest(format, "(0+\.?0+)?%")
			Matches = reExecute(format, "(0+\.?0+)?%")
			RESULT = text(serial * 100, Matches.Item(0).SubMatches(0)) + "%"
		CASE reTest(format, "^\[DBNum\d{1,4}\](.*?)$")
			Matches = reExecute(format, "^\[DBNum(\d{1,4})\](.*?)$")
			DIM value = VAL(Matches.Item(0).SubMatches(0))
			DIM sss = text(serial, Matches.Item(0).SubMatches(1))
			Matches = reExecute(sss, "(\D+)?(\d+)(\D+)?")
			DIM res = ""
			FOR m = 0 TO Matches.Count - 1
				serial = Matches.Item(m).SubMatches(1)
				SELECT value
					CASE 1, 2
						DIM n[][9] = "〇", "一", "二", "三", "四", "五", "六", "七", "八", "九", _
										"", "壱", "弐", "参", "四", "伍", "六", "七", "八", "九"
						DIM a[][3] = "", "十", "百", "千",  _
										"", "拾", "百", "阡"
						DIM b[][3] = "", "万", "億", "兆", _
										"", "萬", "億", "兆"
						DIM r = ""
						DIM j = 0
						type = value - 1
						REPEAT
							DIM str = ""
							DIM n4 = serial MOD 10000
							FOR i = LENGTH(n4) TO 1 STEP -1
								s = COPY(n4, i, 1)
								IFB s = 1 AND a[type][LENGTH(n4)-i] <> "" THEN
									str = IIF(s, a[type][LENGTH(n4)-i], "") + str
								ELSE	
									str = n[type][s] + IIF(s, a[type][LENGTH(n4)-i], "") + str
								ENDIF
							NEXT
							IF str <> "" THEN r = str + b[type][j] + r
							j = j + 1
							serial = INT(serial / 10000)
						UNTIL serial = 0
						res = res + Matches.Item(m).SubMatches(0) + r + Matches.Item(m).SubMatches(2)
					CASE 3
						res = res + Matches.Item(m).SubMatches(0) + STRCONV(serial, SC_FULLWIDTH) + Matches.Item(m).SubMatches(2)
					CASE 4
						res = res + Matches.Item(m).SubMatches(0) + STRCONV(serial, SC_HALFWIDTH) + Matches.Item(m).SubMatches(2)
				SELEND
			NEXT
			RESULT = res
		CASE reTest(format, "^(.*?)(AM\/PM|am\/pm|A\/P|a\/p)(.*?)$")
			Matches = reExecute(format, "^(.*?)(AM\/PM|am\/pm|A\/P|a\/p)(.*?)$")
			DIM array = SPLIT(Matches.Item(0).SubMatches(1), "/")
			ampm = array[IIF(serial - INT(serial) >= 0.5, 1, 0)]
			hour12 = TRUE
			res = ""
			WITH Matches.Item(0)
				res = text(serial, .SubMatches(0), hour12) + ampm + text(serial, .SubMatches(2), hour12)
			ENDWITH
			RESULT = res
		CASE reTest(format, "([^ymdagehns]{0,})?(([ymdagehns])\3{0,})([^ymdagehns]+)?")
			Matches = reExecute(format, "([^ymdagehns]{0,})?(([ymdagehns])\3{0,})([^ymdagehns]+)?")
			FOR n = 0 TO Matches.Count - 1
				IF n = 0 THEN res = Matches.Item(n).SubMatches(0)
			NEXT
			FOR n = 0 TO Matches.Count - 1
				WITH Matches.Item(n)
					res = res + text(serial, .SubMatches(1), hour12) + .SubMatches(3)
				ENDWITH
			NEXT
			RESULT = res
		CASE format = "0/0"
			DIM separator = POS(".", serial)
			DIM g = 0
			IFB separator <> 0 THEN
				DIM keta = LENGTH(serial)
				DIM shift = POWER(10, keta - separator)
				IFB shift >= POWER(10, 15) THEN
					DIM position = 0
					FOR i = 0 TO 14
						IFB serial * POWER(10, i) - serial >= 1 THEN
							position = i
							BREAK
						ENDIF
					NEXT
					tmp = serial * POWER(10, position)
					FOR i = 1 TO 15
						r = (tmp * POWER(10, i)) / serial - (tmp / serial)
						a1 = tmp * POWER(10, i) - tmp
						IF a1 = INT(a1) THEN BREAK 
					NEXT
					DIM frac[] = a1, r
					g = GCD(frac)
					RESULT = (a1/g) + "/" + (r/g)
				ELSE
					DIM molecule = serial * shift	// 分子
					DIM denominator = shift		// 分母
					DIM nums[] = molecule, denominator
					g = GCD(nums)
					molecule = molecule / g
					denominator = denominator / g
					RESULT = molecule + "/" + denominator
				ENDIF
			ELSE
				RESULT = serial + "/1"
			ENDIF
		CASE reTest(format, "(0+)\.?(0+)?") AND UBound(SPLIT(format, ".")) <= 1 
			Matches = reExecute(format, "(0+)\.?(0+)?")
			len1 = LENGTH(Matches.Item(0).SubMatches(0))
			len2 = LENGTH(Matches.Item(0).SubMatches(1))
			DIM arr[] = LENGTH(INT(serial)), len1
			IFB POS(".", format) THEN
				RESULT = REPLACE(FORMAT(serial, CALCARRAY(arr, CALC_MAX) + len2 + 1, len2), " ", "0")
			ELSE
				RESULT = REPLACE(FORMAT(serial, CALCARRAY(arr, CALC_MAX)), " ", "0")
			ENDIF
	SELEND
FEND

//////////////////////////////////////////////////
// 【引数】
//   str : 時刻文字列。hh:nn:ss AM/PM、hh:nn AM/PM、hh AM/PM、hh:nn:ss、hh:nn、hh時nn分ss秒、hh時nn分のいずれかの形式を指定。
// 【戻り値】
//   シリアル値　（例）0…00:00:00、0.5…12:00:00、0.999988425925926…23:59:59
//////////////////////////////////////////////////
FUNCTION timeValue(str)
	DIM serial = 0
	DIM Matches
	DIM pattern = "(\d+)"
	DIM hh = "(0?[0-9]|1[0-2])"
	DIM ampm = "([AP]M|[ap]m)"
	SELECT TRUE
		CASE reTest(str, "\b" + hh + ":" + pattern + ":" + pattern + " " + ampm + "\b")
			Matches = reExecute(str, "\b" + hh + ":" + pattern + ":" + pattern + " " + ampm + "\b")
			WITH Matches.Item(0)
				serial = timeValue(.SubMatches(0) + " " + .SubMatches(3)) + VAL(.SubMatches(1)) / 1440 + VAL(.SubMatches(2)) / 86400
			ENDWITH
		CASE reTest(str, "\b" + hh + ":" + pattern + " " + ampm + "\b")
			Matches = reExecute(str, "\b" + hh + ":" + pattern + " " + ampm + "\b")
			WITH Matches.Item(0)
				serial = timeValue(.SubMatches(0) + " " + .SubMatches(2)) + VAL(.SubMatches(1)) / 1440
			ENDWITH
		CASE reTest(str, "\b" + hh + " " + ampm + "\b")
			Matches = reExecute(str, "\b" + hh + " " + ampm + "\b")
			WITH Matches.Item(0)
				serial = VAL(.SubMatches(0) MOD 12) + IIF(reTest(.SubMatches(1), "AM|am"), 0, 12)
				serial = serial / 24
			ENDWITH
		CASE reTest(str, "\b" + pattern + ":" + pattern + ":" + pattern + "\b")
			Matches = reExecute(str, "\b" + pattern + ":" + pattern + ":" + pattern + "\b")
			WITH Matches.Item(0)
				serial = VAL(.SubMatches(0)) / 24 + VAL(.SubMatches(1)) / 1440 + VAL(.SubMatches(2)) / 86400
			ENDWITH
		CASE reTest(str, "\b" + pattern + ":" + pattern + "\b")
			Matches = reExecute(str, "\b" + pattern + ":" + pattern + "\b")
			WITH Matches.Item(0)
				serial = VAL(.SubMatches(0)) / 24 + VAL(.SubMatches(1)) / 1440
			ENDWITH
		CASE reTest(str, "\b" + pattern + "時" + pattern + "分" + pattern + "秒")
			Matches = reExecute(str, "\b" + pattern + "時" + pattern + "分" + pattern + "秒")
			WITH Matches.Item(0)
				serial = VAL(.SubMatches(0)) / 24 + VAL(.SubMatches(1)) / 1440 + VAL(.SubMatches(2)) / 86400
			ENDWITH
		CASE reTest(str, "\b" + pattern + "時" + pattern + "分")
			Matches = reExecute(str, "\b" + pattern + "時" + pattern + "分")
			WITH Matches.Item(0)
				serial = VAL(.SubMatches(0)) / 24 + VAL(.SubMatches(1)) / 1440
			ENDWITH
		DEFAULT
			serial = ERR_VALUE
	SELEND
	RESULT = serial - INT(serial)
FEND

//////////////////////////////////////////////////
// 【引数】
//   arrayname : 上限値を求める配列の名前
//   dimension : 返す次元を示す整数
// 【戻り値】
//   配列の上限値
//////////////////////////////////////////////////
FUNCTION UBound(arrayname[], dimension = 1)
	RESULT = EVAL("RESIZE(arrayname" + strRepeat("[0]", dimension - 1) + ")")
FEND

使用関数

マウスカーソル下のスクロールバー情報を取得

結果

使用関数

歌ネットから歌詞を取得してテキストファイルに保存

CONST ssfDESKTOP = 0

DIM IE = CREATEOLEOBJ("InternetExplorer.Application")
IE.Visible = TRUE
IE.Navigate("https://www.uta-net.com/song/280568/")
BusyWait(IE)

DIM element, elements, name, lyrics

element = IE.document.getElementById("view_kashi")
elements = element.getElementsByClassName("title")
name = TRIM(elements.Item(0).innerText)

element = IE.document.getElementById("kashi_area")
lyrics = element.innerText

IE.Quit

DIM Shell = CREATEOLEOBJ("Shell.Application")
DIM Folder = Shell.NameSpace(ssfDESKTOP)
DIM path = Folder.Self.Path
DIM FSO = CREATEOLEOBJ("Scripting.FileSystemObject")
path = uniqueFilename(FSO.BuildPath(path, name + ".txt"))

DIM FID = FOPEN(path, F_READ OR F_WRITE)
FPUT(FID, lyrics)
FCLOSE(FID)

//////////////////////////////////////////////////
// 【引数】
//   str : 正規表現による検索の対象となる文字列
//   Pattern : 正規表現で使用するパターンを設定
//   IgnoreCase : 大文字・小文字を区別しない場合はTrue、区別する場合はFalse
//   Global : 文字列全体を検索する場合はTrue、しない場合はFalse
// 【戻り値】
//   正規表現にマッチするかどうかを示すブール値
//////////////////////////////////////////////////
FUNCTION reTest(str, Pattern, IgnoreCase = TRUE, Global = TRUE)
	DIM re = CREATEOLEOBJ("VBScript.RegExp")
	re.Pattern = Pattern
	re.IgnoreCase = IgnoreCase
	re.Global = Global
	RESULT = re.Test(str)
FEND

//////////////////////////////////////////////////
// 【引数】
//   path : ファイルのパス
// 【戻り値】
//   重複しないファイル名
//////////////////////////////////////////////////
FUNCTION uniqueFilename(path)
	DIM FSO = CREATEOLEOBJ("Scripting.FileSystemObject")
	IFB FSO.FileExists(path) THEN
		DIM fol = FSO.GetParentFolderName(path)
		DIM filename = FSO.GetBaseName(path)
		DIM extension = FSO.GetExtensionName(path)
		DIM i = 2
		WHILE FSO.FileExists(FSO.BuildPath(fol, filename + " (" + i + ")." + extension))
			i = i + 1
		WEND
		RESULT = FSO.BuildPath(fol, filename + " (" + i + ")." + extension)
	ELSE
		RESULT = path
	ENDIF
FEND

使用関数

ファイルを開いているプロセスを調べる

SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")

CONST TemporaryFolder = 2

DIM FSO = CREATEOLEOBJ("Scripting.FileSystemObject")

WITH FSO
	DIM Folder = .GetSpecialFolder(TemporaryFolder)
	DIM folderspec = Folder.Path
	DIM filename = .GetTempName
	DIM path = .BuildPath(folderspec, filename)
ENDWITH

DIM Shell = CREATEOLEOBJ("Shell.Application")
Shell.FileRun()

DIM ID = GETID("ファイル名を指定して実行", "#32770")

SENDSTR(ID, "cmd /c openfiles /query /fo CSV > " + path)
CLKITEM(ID, "OK", CLK_BTN)
SLEEP(0.500)

REPEAT
	SLEEP(0.100)
UNTIL GETID("C:\WINDOWS\system32\cmd.exe", "ConsoleWindowClass") = -1

DIM FID = FOPEN(path, F_READ)

TRY
	DIM ID2 = GETID("使用中", "OperationStatusWindow")

GETITEM(ID2, ITM_ACCTXT, 1)
	DIM str = ALL_ITEM_LIST[1]
	
	DIM sep = IIF(POS("フォルダー", STATUS(ID2, ST_TITLE)) <> 0, "\", "")
	DIM msg = "■" + str + "<#CR>"
	
	FOR r = 5 TO FGET(FID, F_LINECOUNT)
		IF POS("\" + str + sep,  FGET(FID, r, 3)) <> 0 THEN
			msg = msg + "ID：" + FGET(FID, r, 1) + ", プロセス名：" + FGET(FID, r, 2) + "<#CR>"
		ENDIF
	NEXT
	FCLOSE(FID)

REPEAT
		FUKIDASI(TRIM(msg))
		SLEEP(0.100)
	UNTIL GETID("使用中", "OperationStatusWindow") = -1
FINALLY
	FSO.DeleteFile(path)
ENDTRY

//////////////////////////////////////////////////
// 【引数】
// 【戻り値】
//////////////////////////////////////////////////
PROCEDURE forceQuit()
	EXITEXIT
FEND

使用関数

SETHOTKEY関数（1行目）: ホットキーを設定します。
定数定義（3行目）
DIM （5, 8, 9, 10, 11, 14, 17, 27, 30, 33行目他2行）: ローカル変数を宣言します。
CREATEOLEOBJ関数 (スクリプト関数) （5, 14行目）: COMオブジェクトを生成します。
WITH文（7行目）
Shell.FileRun メソッド（15行目）: 「ファイル名を指定して実行」ウィンドウを開きます。
GETID関数（17, 25, 30, 48行目）: 指定したウィンドウのIDを取得します。第一引数に取得したいウィンドウのタイトル（一部でも可）を指定します。
SENDSTR関数（19行目）: 文字列を送信します。
CLKITEM関数（20行目）: アイテムをクリックします。
SLEEP関数（21, 24, 47行目）: 処理を待機します。
REPEAT文（23, 24, 25, 45, 46, 47, 48行目）: ループ処理を行います。ループの終わりに条件判定を行うので、最低1度は処理が実行されます。後判定。
FOPEN関数（27行目）: テキストファイルを開き、ファイルIDを取得します。
例外処理（29行目）
GETITEM関数（32行目）: キャプション文字やリスト等をすべて取得します。
IIF関数 (自作関数) （35行目）: 式を評価して値を返します。
POS関数 (スクリプト関数) （35, 39行目）: 文字列内で部分文字列が最初に現れる位置を返します。
STATUS関数（35行目）: ウィンドウの各種状態を返します。
FOR-TO文（38, 39, 40, 41, 42行目）: 条件が真の間、処理を繰り返し実行します。途中でループを抜けたいときはBREAK文を使います。
FGET関数（38, 39, 40行目）: テキストファイルの読み込みを行います。
IFB文（39行目）: IFB-ENDIF文は条件によって処理を分岐させたいときに利用します。ELSEIF文で条件、処理を複数書くことができます。処理が1文のときはIF文でも書くことができます。
FCLOSE関数（43行目）: テキストファイルを閉じます。
FUKIDASI関数（46行目）: メッセージを吹出しに表示します。
TRIM関数（46行目）: 文字列の両端の空白と制御文字を取り除きます。
特殊文字（33行目）

Cドライブの使用済み容量を取得

num = TRIM(POWERSHELL("(Get-PSDrive C).Used /1GB"))
PRINT ROUND(num) + "GB"

結果

使用関数

Dドライブの空き容量を取得

num = TRIM(POWERSHELL("(Get-PSDrive D).Free /1GB"))
PRINT ROUND(num) + "GB"

結果

使用関数

バッテリー残量を取得（PowerShell）

battery = TRIM(POWERSHELL("(Get-WmiObject Win32_Battery).(<#DBL>EstimatedChargeRemaining<#DBL>)"))
PRINT battery + "％"

使用関数

現在設定している壁紙のパスを取得（コマンドプロンプト）

使用関数

現在設定している壁紙のパスを取得（WMI）

使用関数

システム起動時間を取得（PowerShell）

PRINT TRIM(POWERSHELL("[Management.ManagementDateTimeConverter]::ToDateTime((Get-WmiObject Win32_OperatingSystem).LastBootUpTime)"))

結果

使用関数

無線LANのインターフェイス情報を取得（コマンドプロンプト）

HASHTBL LAN

str = SPLIT(DOSCMD("netsh wlan show interface"), "<#CR>")

FOR n = 0 TO UBound(str)
	IFB POS(":", str[n]) THEN
		arr = SPLIT(str[n], ":")
		LAN[TRIM(arr[0])] = TRIM(arr[1])
	ENDIF
NEXT

PRINT "名前<#TAB><#TAB><#TAB><#TAB>" + LAN["名前"]
PRINT "説明<#TAB><#TAB><#TAB><#TAB>" + LAN["説明"]
PRINT "GUID<#TAB><#TAB><#TAB><#TAB>" + LAN["GUID"]
PRINT "物理アドレス<#TAB><#TAB><#TAB>" + LAN["物理アドレス"]
PRINT "状態<#TAB><#TAB><#TAB><#TAB>" + LAN["状態"]
PRINT "SSID<#TAB><#TAB><#TAB><#TAB>" + LAN["SSID"]
PRINT "BSSID<#TAB><#TAB><#TAB><#TAB>" + LAN["BSSID"]
PRINT "ネットワークの種類<#TAB><#TAB>" + LAN["ネットワークの種類"]
PRINT "無線の種類<#TAB><#TAB><#TAB>" + LAN["無線の種類"]
PRINT "認証<#TAB><#TAB><#TAB><#TAB>" + LAN["認証"]
PRINT "暗号<#TAB><#TAB><#TAB><#TAB>" + LAN["暗号"]
PRINT "接続モード<#TAB><#TAB><#TAB>" + LAN["接続モード"]
PRINT "チャネル<#TAB><#TAB><#TAB>" + LAN["チャネル"]
PRINT "受信速度 (Mbps)<#TAB><#TAB><#TAB>" + LAN["受信速度 (Mbps)"]
PRINT "送信速度 (Mbps)<#TAB><#TAB><#TAB>" + LAN["送信速度 (Mbps)"]
PRINT "シグナル<#TAB><#TAB><#TAB>" + LAN["シグナル"]
PRINT "プロファイル<#TAB><#TAB><#TAB>" + LAN["プロファイル"]
PRINT "ホストされたネットワークの状態<#TAB>" + LAN["ホストされたネットワークの状態"]

結果

使用関数

無線LANのプロファイル情報を取得（コマンドプロンプト）

HASHTBL LAN1
HASHTBL LAN2

str = SPLIT(DOSCMD("netsh wlan show interface"), "<#CR>")

FOR n = 0 TO UBound(str)
	IFB POS(":", str[n]) THEN
		arr = SPLIT(str[n], ":")
		LAN1[TRIM(arr[0])] = TRIM(arr[1])
	ENDIF
NEXT

str =SPLIT(DOSCMD("netsh wlan show profiles name=" + LAN1["SSID"] + " key=clear"), "<#CR>")

FOR n = 0 TO UBound(str)
	IFB POS(":", str[n]) THEN
		arr = SPLIT(str[n], ":")
		LAN2[TRIM(arr[0])] = TRIM(arr[1])
	ENDIF
NEXT

PRINT "プロファイル情報"
PRINT "----------"
PRINT "バージョン<#TAB><#TAB><#TAB>" + LAN2["バージョン"]
PRINT "種類<#TAB><#TAB><#TAB><#TAB>" + LAN2["種類"]
PRINT "名前<#TAB><#TAB><#TAB><#TAB>" + LAN2["名前"]
PRINT "接続モード<#TAB><#TAB><#TAB>" + LAN2["接続モード"]
PRINT "ネットワーク ブロードキャスト<#TAB>" + LAN2["ネットワーク ブロードキャスト"]
PRINT "AutoSwitch<#TAB><#TAB><#TAB>" + LAN2["AutoSwitch"]
PRINT "MAC ランダム化<#TAB><#TAB><#TAB>" + LAN2["MAC ランダム化"]
PRINT
PRINT "接続の設定"
PRINT "----------"
PRINT "SSID の数<#TAB><#TAB>" + LAN2["SSID の数"]
PRINT "SSID 名<#TAB><#TAB><#TAB>" + LAN2["SSID 名"]
PRINT "ネットワークの種類<#TAB>" + LAN2["ネットワークの種類"]
PRINT "無線の種類<#TAB><#TAB>" + LAN2["無線の種類"]
PRINT "ベンダー拡張<#TAB><#TAB>" + LAN2["ベンダー拡張"]
PRINT
PRINT "セキュリティの設定"
PRINT "----------"
PRINT "認証<#TAB><#TAB><#TAB>" + LAN2["認証"]
PRINT "暗号<#TAB><#TAB><#TAB>" + LAN2["暗号"]
PRINT "セキュリティ キー<#TAB>" + LAN2["セキュリティ キー"]
PRINT "主要なコンテンツ<#TAB>" + LAN2["主要なコンテンツ"]
PRINT
PRINT "コスト設定"
PRINT "----------"
PRINT "コスト<#TAB><#TAB>" + LAN2["コスト"]
PRINT "混雑<#TAB><#TAB>" + LAN2["混雑"]
PRINT "データ制限間近<#TAB>" + LAN2["データ制限間近"]
PRINT "データ制限超過<#TAB>" + LAN2["データ制限超過"]
PRINT "ローミング<#TAB>" + LAN2["ローミング"]
PRINT "コスト ソース<#TAB>" + LAN2["コスト ソース"]

結果

使用関数

公開日: 2018年10月28日
更新日: 2024年11月9日

TRIM関数

制御文字

使い方

両端の制御文字を取り除く

一部の制御文字のみ取り除く

文中の制御文字を取り除く

全角スペース

制御文字

プログラム実行例

システムの起動時間を取得

「Yahoo!テレビ.Gガイド [テレビ番組表]」から番組表データを取得する

マウスカーソル下のスクロールバー情報を取得

歌ネットから歌詞を取得してテキストファイルに保存

ファイルを開いているプロセスを調べる

Cドライブの使用済み容量を取得

Dドライブの空き容量を取得

バッテリー残量を取得（PowerShell）

現在設定している壁紙のパスを取得（コマンドプロンプト）

現在設定している壁紙のパスを取得（WMI）

システム起動時間を取得（PowerShell）

無線LANのインターフェイス情報を取得（コマンドプロンプト）

無線LANのプロファイル情報を取得（コマンドプロンプト）

検索フォーム

設定

最近の投稿・更新

タグ一覧

このページを共有する

寄付・支援