1. 仮想キー
2. キーボード
3. 仮想キーコード

キーボードを操作します。キーの状態を調べるにはGETKEYSTATE関数、文字列を送信する場合はSENDSTR関数を使います。

構文

1. void = KBD( 仮想KEY, 状態, ms )

引数

仮想KEY （#kbd）必須

仮想KEYコード、もしくはUNICODE

状態 （#kbd = CLICK）省略可

CLICK（0：デフォルト）,DOWN（1）,UP（2）

ms （Single = 0）省略可

実行までの待ち時間 （ミリセカンド）

戻り値

SENDSTR関数との違い

SENDSTR関数は文字列を送信するのに対し、KBD関数はキー入力を行います。そのためIMEの状態（日本語入力か半角入力かなど）によって入力される文字が変わってきます。入力する文字列が決まっている場合はSENDSTR関数、キーボードを押したい場合はKBD関数を使いましょう。

以下に示す2つのプログラムはメモ帳を起動し、AIUEOを順に押してく例。同じAIUEOと押していく処理でもIMEの状態で結果が変わります。

2つのプログラムの違いはGETKEYSTATE関数の前に!があるかないかだけです。日本語入力と半角入力を意図的に変えています。

まず半角で入力したとき。

DIM ID = EXEC("notepad")
CTRLWIN(ID, ACTIVATE)

IF GETKEYSTATE(TGL_IME) THEN KBD(VK_KANJI,CLICK)

KBD(VK_A)
KBD(VK_I)
KBD(VK_U)
KBD(VK_E)
KBD(VK_O)

結果

プレーンテキスト

aiueo

Copyaiueo

次に日本語で入力したとき。

DIM ID = EXEC("notepad")
CTRLWIN(ID, ACTIVATE)

IF !GETKEYSTATE(TGL_IME) THEN KBD(VK_KANJI,CLICK)

KBD(VK_A)
KBD(VK_I)
KBD(VK_U)
KBD(VK_E)
KBD(VK_O)

結果

プレーンテキスト

あいうえお

Copyあいうえお

仮想キーコード一覧

以下は日本語環境で主流の109キーボードのキー配列を表したものです。

以下の画像は直接入力モードでCapsLockが解除されているときの入力値をまとめたものです。赤字が仮想キーコードの値、青字がShiftキーを押しながら入力したときの文字、緑字はテンキーでNumLockを解除しているときの値です。

キー名にあるOEM（Originalオリジナル Equipmentイクイップメント Manufacturerマニュファクチュアラー）固有とはキーボードメーカーがボタンを拡張できるように予め予約されたキーのことです。

以下は仮想キーコードをまとめた表です。Shift列はShiftを押しながら対応キーを押したときに入力される文字です。これらの入力方法はショートカットキーを実行（修飾子キーが1つ）を参照してください。

マウス操作はBTN関数を使います。

使い方

キーをクリック

KBD関数の第一引数にクリックするキーの仮想キーコードを指定します。

KBD(キーコード)

以下はAをクリックする例です。第一引数のみ指定した場合はそのキーをクリックします。

KBD(VK_A)

キー入力が反応しない場合は、対象のウィンドウがアクティブになっていない可能性があるので、その場合はまずCTRLWIN関数でアクティブにしてからキー入力をします。以下はキー入力の対象がメモ帳の場合の書き方です。

DIM ID = GETID("メモ帳")
CTRLWIN(ID, ACTIVATE)

KBD(VK_A)

キーを長押しする（一定時間押し続けてから離す）

Bを3秒間押し続けてから離します。

KBD(VK_B, DOWN)
SLEEP(3.000)
KBD(VK_B, UP)

第三引数に時間を指定するとその時間だけ待機してから実行されるので、以下のように書き換えることもできます。時間はミリ秒なので3秒は1000倍して3000ミリ秒となります。

KBD(VK_B, DOWN)
KBD(VK_B, UP, 3000)

一定時間待機後にキーをクリック

1秒間待機してからCをクリックします。

KBD(VK_C, CLICK, 1000)

ショートカットキーを実行

ショートカットキーを実行するにはSCKEY関数を使うのが簡単ですが、KBD関数でも修飾子キーを押した状態で仮想キーを押すことで実行することもできます。修飾子キーとはCtrl、Shift、Alt、のことです。

修飾子キーが単数

修飾子キーが単数の場合、KBD関数で修飾子キーを押し下げた状態のままにし仮想キーをクリック、修飾子キーを離すという動作を行うことで実行することができます。

これをプログラムで書くと以下のようになります。

KBD(修飾子キー, DOWN)
KBD(仮想キーコード[, CLICK])
KBD(修飾子キー, UP)

SCKEY関数を使って書くと以下のようになります。

SCKEY(0, 修飾子キー, 仮想キーコード)

仮想キーコード一覧でShift列はShiftを押したまま対応キーを押すことで実行でき、これをプログラムにすると以下のようになります。対応キーには仮想キーコード一覧の値、もしくは変数名を指定します。

KBD(VK_SHIFT, DOWN)
KBD(対応キー[, CLICK])
KBD(VK_SHIFT, UP)

例えば、_（アンダーバー）を入力するには、キーボードでShift＋\と入力するようにKBD関数でもShiftを押したまま\をクリックする処理を書きます。

\（対応キー）または_（Shift列）を仮想キーコード一覧の表から探すと、値が226のVK_OEM_102（OEM102キー）が該当するキーであることがわかり、Shiftと一緒に押すことで_を入力することができます。実行した結果がわかるように、以下のプログラムではメモ帳に入力しています。

DIM ID = EXEC("notepad")
CTRLWIN(ID, ACTIVATE)

KBD(VK_SHIFT, DOWN)
KBD(VK_OEM_102)
KBD(VK_SHIFT, UP)

修飾子キーが複数

修飾子キーが複数になっても基本的に1つのときと同じです。まずすべての修飾子キーを押したままの状態にしてから仮想キー（修飾子キー以外は）をクリックし、これまでに押した修飾子キーをすべて離します。仮想キーは修飾子キーをすべて押した状態にしたあとにクリックします。

KBD(修飾子キー1, DOWN)
KBD(修飾子キー2, DOWN)
KBD(仮想キーコード[, CLICK])
KBD(修飾子キー2, UP)
KBD(修飾子キー1, UP)

以下はCtrl＋Shift＋ESCを押し、タスクマネージャーを起動します。修飾子キーのCtrlとShiftを押したままの状態にしてからESCをクリックし、修飾子キーを離します。

KBD(VK_CTRL, DOWN)
KBD(VK_SHIFT, DOWN)
KBD(VK_ESC, CLICK)
KBD(VK_CTRL, UP)
KBD(VK_SHIFT, UP)

修飾子キーが2つの場合も、SCKEY関数を使うと以下のように書けます。

SCKEY(0, 修飾子キー1, 修飾子キー2, 仮想キーコード)

タスクマネージャーの起動は以下のようになります。

SCKEY(0, VK_CTRL, VK_SHIFT, VK_ESC)

修飾子キーが3つのときは以下のようになります。

KBD(修飾子キー1, DOWN)
KBD(修飾子キー2, DOWN)
KBD(修飾子キー3, DOWN)
KBD(仮想キーコード[, CLICK])
KBD(修飾子キー3, UP)
KBD(修飾子キー2, UP)
KBD(修飾子キー1, UP)

SCKEY関数に書き換える場合は以下のようになります。

SCKEY(0, 修飾子キー1, 修飾子キー2, 修飾子キー3, 仮想キーコード)

キーに変数を使う

キーに変数を使う場合は仮想キーコード一覧の定数名に対応する値を探し、KBD関数の第一引数にその値を指定します。

例えばVK_Aに対応する値は65なので、Aと入力するには以下のように書きます。

KBD(65)

これは以下のように仮想キーコードで指定するのと同じ結果を返します。

KBD(VK_A)

変数の場合キーコードで指定するのとは違い、連続する文字列を簡単に指定することもできます。

以下はA～Fを仮想キーコードで指定する書き方です。

KBD(VK_A)
KBD(VK_B)
KBD(VK_C)
KBD(VK_D)
KBD(VK_E)
KBD(VK_F)

変数を使って書くと以下のようになります。

FOR key = 65 TO 70
	KBD(key)
NEXT

仮想キーコードは定数なので以下のように書くとわかりやすくなります。

FOR key = VK_A TO VK_F
	KBD(key)
NEXT

プログラム実行例

メモ帳の右クリックメニューを表示させる

DIM ID = EXEC("notepad")
CTRLWIN(ID, ACTIVATE)

KBD(VK_APPS, CLICK, 1000)

パソコンの音量を上げる

パソコンの音量を上げます。Windows2000以降のOSの場合は仮想キーの操作で音量を上げ、Windows 2000より前のOSの場合はボリューム調整ツールを操作することで音量を上げます。

IFB KINDOFOS() >= 12 THEN
	KBD(VK_VOLUME_UP)
ELSE
	ID = EXEC("SNDVOL32.exe /t")
	SETSLIDER(ID, GETSLIDER(ID, 1) - 10)
ENDIF

パソコンの音量を下げる

パソコンの音量を下げます。Windows2000以降のOSの場合は仮想キーの操作で音量を下げ、Windows 2000より前のOSの場合はボリューム調整ツールを操作することで音量を下げます。

IFB KINDOFOS() >= 12
	KBD(VK_VOLUME_DOWN)
ELSE
	ID = EXEC("SNDVOL32.exe /t")
	SETSLIDER(ID, GETSLIDER(ID, 1) + 10)
ENDIF

特定のキーを連打する

SETHOTKEY(VK_ESC, EMPTYPARAM, "forceQuit")
SETHOTKEY(VK_SPACE, EMPTYPARAM, "toggle")

PUBLIC flg = FALSE

WHILE TRUE
	DIM msg = "Spaceキーで切り替え<#CR>ESCキーで終了<#CR>"
	IFB flg THEN
		FUKIDASI(msg + "連打中")
		KBD(VK_A, CLICK)
		SLEEP(0.100)
	ELSE
		FUKIDASI(msg + "停止中")
	ENDIF
WEND

PROCEDURE forceQuit()
	EXITEXIT
FEND

PROCEDURE toggle()
	flg = !flg
	SLEEP(0.500)
FEND

日本語入力をONにする

現在の入力モードが直接入力であれば半角/全角キーを押して日本語入力に切り替えます。

IF !GETKEYSTATE(TGL_IME) THEN KBD(VK_KANJI, CLICK)

日本語入力をOFFにする

現在の入力モードが日本語入力であれば半角/全角キーを押して直接入力に切り替えます。

IF GETKEYSTATE(TGL_IME) THEN KBD(VK_KANJI, CLICK)

NumLockをONにする

NumLockの状態を確認し、OFFであればNumLockキーを押してONにします。

IF !GETKEYSTATE(TGL_NUMLOCK) THEN KBD(VK_NUMLOCK)

NumLockをOFFにする

NumLockの状態を確認し、ONであればNumLockキーを押してOFFにします。

IF GETKEYSTATE(TGL_NUMLOCK) THEN KBD(VK_NUMLOCK)

CapsLockをONにする

CapsLockの状態を確認し、OFFであればCapsLockキーを押してONにします。

IF !GETKEYSTATE(TGL_CAPSLOCK) THEN KBD(VK_CAPITAL)

CapsLockをOFFにする

CapsLockの状態を確認し、ONであればCapsLockキーを押してOFFにします。

IF GETKEYSTATE(TGL_CAPSLOCK) THEN KBD(VK_CAPITAL)

ScrollLockをONにする

IF !GETKEYSTATE(TGL_SCROLLLOCK) THEN KBD(VK_SCROLL)

ScrollLockをOFFにする

IF GETKEYSTATE(TGL_SCROLLLOCK) THEN KBD(VK_SCROLL)

カナロックをONにする

IF !GETKEYSTATE(TGL_KANALOCK) THEN KBD(VK_KANA)

カナロックをOFFにする

IF GETKEYSTATE(TGL_KANALOCK) THEN KBD(VK_KANA)

関連記事

SCKEY関数 (スクリプト関数)

ショートカットキーを実行します。

LOCKHARD関数 (スクリプト関数)

LOCKHARDEX関数 (スクリプト関数)