Value

構文
Range.Value( [RangeValueDataType] )

Range.Value( [RangeValueDataType] ) = 設定値
引数
RangeValueDataType (xlRangeValueDataType
セル範囲の値のデータ型を指定します。
戻り値

Range オブジェクトを返す可能性のあるメソッド・プロパティ

Range.Value プロパティ (Excel)
Value (Excel)
Application.Cells プロパティ (Excel)
Range.Find メソッド (Excel)
Range.SpecialCells メソッド (Excel)
Range.Columns プロパティ (Excel)
Range.CurrentRegion プロパティ (Excel)
Range.End プロパティ (Excel)
Range.EntireColumn プロパティ (Excel)
Range.EntireRow プロパティ (Excel)
Range.Item プロパティ (Excel)
Range.Offset プロパティ (Excel)
Range.Resize プロパティ (Excel)
Range.Rows プロパティ (Excel)

定数一覧

xlRangeValueDataType 列挙

名前説明
xlRangeValueDefault10Rangeオブジェクトが空の場合はEmpty値が返されます。Rangeオブジェクトに複数のセルが含まれているときは値の配列が返されます。
xlRangeValueXMLSpreadsheet11指定したXMLスプレッドシート形式のRangeオブジェクトの値、書式設定、数式、名前を返します。
xlRangeValueMSPersistXML12指定したXML形式のRangeオブジェクトのレコードセットの表示を返します。
CONST xlRangeValueDefault = 10
CONST xlRangeValueXMLSpreadsheet = 11
CONST xlRangeValueMSPersistXML = 12

プログラム実行例

セルに文字列を入力(A1形式)

DIM Excel = CREATEOLEOBJ("Excel.Application")
Excel.Visible = TRUE

ID = GETID("Microsoft Excel")
CTRLWIN(ID, ACTIVATE)

Excel.Workbooks.Add()
Excel.Range("A1").Value = "UWSC"

// Excel.DisplayAlerts = FALSE
// Excel.Quit
  1. CREATEOLEOBJ
  2. Excel.Application.Visible
  3. GETID
  4. CTRLWIN
  5. Excel.Workbooks.Add
  6. Excel.Application.Range
  7. Excel.Range.Value
  8. Excel.Application.DisplayAlerts
解説
  1. 1-2行目
    DIM Excel = CREATEOLEOBJ("Excel.Application")Excel.Visible = TRUE
    Excelを起動する。
  2. 4-5行目
    ID = GETID("Microsoft Excel")CTRLWIN(ID, ACTIVATE)
    Excelをアクティブ化する。
  3. 7行目
    Excel.Workbooks.Add()
    新規ブックの作成。
  4. 8行目
    Excel.Range("A1").Value = "UWSC"
    セルA1に「UWSC」と代入。
  5. 10行目
    // Excel.DisplayAlerts = FALSE
    終了時に確認メッセージを表示しない。
  6. 11行目
    // Excel.Quit
    Excelを終了する。

セルに文字列を入力(R1C1形式)

Excel = CREATEOLEOBJ("Excel.Application")
Excel.Visible = TRUE

ID = GETID("Microsoft Excel")
CTRLWIN(ID, ACTIVATE)

Excel.Workbooks.Add()
Excel.Cells(1, 1).Value = "UWSC"

// Excel.DisplayAlerts = FALSE
// Excel.Quit
  1. CREATEOLEOBJ
  2. Excel.Application.Visible
  3. GETID
  4. CTRLWIN
  5. Excel.Workbooks.Add
  6. Excel.Application.Cells
  7. Excel.Range.Value
  8. Excel.Application.Displayalerts
  9. Excel.Application.Quit
解説
  1. 1-2行目
    Excel = CREATEOLEOBJ("Excel.Application")Excel.Visible = TRUE
    Excelを起動。
  2. 4-5行目
    ID = GETID("Microsoft Excel")CTRLWIN(ID, ACTIVATE)
    Excelをアクティブ化
  3. 7行目
    Excel.Workbooks.Add()
    新規ブックの作成
  4. 8行目
    Excel.Cells(1, 1).Value = "UWSC"
    A1セルに「UWSC」と代入する。
  5. 10行目
    // Excel.DisplayAlerts = FALSE
    確認メッセージを表示しない。
  6. 11行目
    // Excel.Quit
    Excelを終了する。

日付の連続データを入力する*

A1セルに「2021/01/01」と入力し、行方向に1日ずつ加算し2021/12/31まで入力します。

A1セルに「2021/01/01」と入力し、[フィル]→[連続データの作成]で範囲を行、種類を日付、増加単位を日、増分値を1、停止値を2021/12/31と設定するのと同様です。

CONST xlCols = 2
CONST xlChronological = 3
CONST xlDay = 1

WITH Excel.Range("A1")
	.Value = "2021/01/01"
	.DataSeries(xlCols, xlChronological, xlDay, 1, "2021/12/31")
	.EntireColumn.AutoFit
ENDWITH
  1. Excel.Range
  2. Excel.Range.Value
  3. Excel.Range.DataSeries
  4. Excel.Range.AutoFit

1〜12月の連続データを作成*

WITH Excel.Range("A1")
	.Value = "1月"
	.AutoFill(.Resize(12))
ENDWITH
  1. Excel.Range
  2. Excel.Range.Value
  3. Excel.Range.AutoFill
  4. Excel.Range.Resize

2ヶ月毎の連続データを入力*

CONST xlColumns = 2
CONST xlChronological = 3
CONST xlMonth = 3

WITH Excel.Range("A1")
	.Value = "2021/01/01"
	.DataSeries(xlColumns, xlChronological, xlMonth, 2, "2021/12/31")
	.EntireColumn.AutoFit
ENDWITH
  1. Excel.Range
  2. Excel.Range.Value
  3. Excel.Range.DataSeries
  4. Excel.Range.EntireColumn
  5. Excel.Range.AutoFit

相対座標

DIM Excel = ExcelBoot()

WITH Excel.Range("E5")
	FOR r = -3 TO 3
		FOR c = -3 TO 3
			DIM Range = .Offset(r, c)
			Range.Value = "(" + r + ", " + c + ")"
			IF r = 0 AND c = 0 THEN Range.Value = "基準セル"
		NEXT
	NEXT
ENDWITH

//////////////////////////////////////////////////
// 【引数】
//   path : 開くファイルのパス名 
// 【戻値】
//   Excelオブジェクト 
//////////////////////////////////////////////////
FUNCTION ExcelBoot(path = "")
	DIM Excel = CREATEOLEOBJ("Excel.Application")
	Excel.Visible = TRUE
	IFB path = "" THEN
		Excel.Workbooks.Add
	ELSE
		DIM FSO = CREATEOLEOBJ("Scripting.FileSystemObject")
		IFB FSO.GetParentFolderName(path) = "" THEN
			path = GET_CUR_DIR + "\" + path
		ENDIF
		Excel.Workbooks.Open(path)
	ENDIF
	RESULT = Excel
FEND
  1. ExcelBoot
  2. Excel.Range.Offset
  3. Excel.Range.Value
結果

アクティブセルに文字列を入力する

DIM Excel = CREATEOLEOBJ("Excel.Application")
Excel.Visible = TRUE
Excel.Workbooks.Add()

DIM Range = Excel.Application.ActiveCell
SLEEP(1.000)
Range.Value = "abc"
SLEEP(3.000)

Excel.Application.DisplayAlerts = FALSE
Excel.Quit
  1. CREATEOLEOBJ
  2. Excel.Application.Visible
  3. Excel.Workbooks.Add
  4. Excel.Application.ActiveCell
  5. SLEEP
  6. Excel.Range.Value
  7. Excel.Application.DisplayAlerts
  8. Excel.Application.Quit